topic Re: Macro do loop if then in New SAS User

Macro do loop if then

torvyle — Tue, 08 Oct 2019 20:54:27 GMT

Hello,

SAS is running the following code but results are not being generated. I'm running Enterprise Guide 7.12.

%macro abc;
	data want;
		set have;
		%do num=1 %to 25;
			%if diag_code&num. in ("Z590", "Z591", "Z598") %then
				dcheck&num.=1;
		%end;
	run;
%mend;
%abc;
run;

Thanks

Re: Macro do loop if then

Reeza — Tue, 08 Oct 2019 21:13:13 GMT

What happens if you use an array instead of macro code here?
Why are you using macros instead of arrays?

Re: Macro do loop if then

Astounding — Tue, 08 Oct 2019 21:19:24 GMT

You could switch to arrays, as suggested. Then you wouldn't need any macro language at all. However, you can get macro language to do the job easily enough by cutting out a couple of percent signs:

%macro abc;
	data want;
		set have;
		%do num=1 %to 25;
			if diag_code&num. in ("Z590", "Z591", "Z598") then
				dcheck&num.=1;
		%end;
	run;
%mend;
%abc

The idea is to have the DATA step process the data. The role of macro language is to make sure that the correct DATA step code gets generated.

Re: Macro do loop if then

Kurt_Bremser — Wed, 09 Oct 2019 08:34:47 GMT

@torvyle wrote:

Hello,

SAS is running the following code but results are not being generated. I'm running Enterprise Guide 7.12.
%macro abc;
	data want;
		set have;
		%do num=1 %to 25;
			%if diag_code&num. in ("Z590", "Z591", "Z598") %then
				dcheck&num.=1;
		%end;
	run;
%mend;
%abc;
run;
Thanks

Do not use the macro language for manipulating data. Macro language is for manipulating code.

Use the data step's tools for this:

data want;
set have;
array diags {*} diag_code1-diag_code25;
array checks {*} dcheck1-dcheck25;
do num = 1 to 25;
  if diags{num} in ("Z590", "Z591", "Z598")
  then checks{num} = 1;
end;
drop num;
run;

Re: Macro do loop if then

torvyle — Wed, 09 Oct 2019 12:41:11 GMT

Thanks, everyone. KurtBremser's solution works too.