topic Re: Equality Comparison on User Defined Formats in New SAS User

Equality Comparison on User Defined Formats

david27 — Wed, 25 Sep 2019 18:07:25 GMT

Please run the below code and check for dataset have2

Why do I get value of flag as "2<1" when all values in nos2 is > nos1?

What am I missing?

Please advise.

Thanks

PROC FORMAT;
VALUE rvsd_format
	5000-10000="5000-10000"
	10000-25000="10000-25000"
;
run;

data have;
input nos1 nos2;
datalines ;	
9544.59 10605.10
8588.00 10781.20
9029.48 11061.31
9831.00 10158.70
9454.00 13380.18
9504.00 15888.00
8400.00 12728.80
6672.00 16516.00
7595.12 14062.24
9951.13 10780.39
;
run;
data have2;
set have;
fmt_nos1=put(nos1,rvsd_format.);
fmt_nos2=put(nos2,rvsd_format.);
if fmt_nos2=fmt_nos1 then flag="Equal";
else if fmt_nos2>fmt_nos1 then flag="2>1";
else flag="2<1";
run;

Re: Equality Comparison on User Defined Formats

Jagadishkatam — Wed, 25 Sep 2019 18:22:22 GMT

Here you are comparing the the character variables because of which it is taking the last else condition

flag="2<1"

You need to compare the numeric variables

Re: Equality Comparison on User Defined Formats

Jagadishkatam — Wed, 25 Sep 2019 18:25:51 GMT

Please try the below code where I used the invalue for creating the informat as 1 and 2 and now you will get the expected result in the flag variable.

PROC FORMAT;
inVALUE rvsd_format
	5000-10000=1
	10000-25000=2
;
run;

data have;
input nos1 nos2;
datalines ;	
9544.59 10605.10
8588.00 10781.20
9029.48 11061.31
9831.00 10158.70
9454.00 13380.18
9504.00 15888.00
8400.00 12728.80
6672.00 16516.00
7595.12 14062.24
9951.13 10780.39
;
run;

data have2;
set have;
fmt_nos1=input(nos1,rvsd_format.);
fmt_nos2=input(nos2,rvsd_format.);
if fmt_nos2=fmt_nos1 then flag="Equal";
else if fmt_nos2>fmt_nos1 then flag="2>1";
else flag="2<1";
run;

Re: Equality Comparison on User Defined Formats

Kurt_Bremser — Wed, 25 Sep 2019 18:33:18 GMT

The first character of "5000-10000" is "5", which comes later in the collating sequence than the first character of "10000-25000" ("1").

So "5000-10000" is "greater" than "10000-25000", when compared as strings.

Re: Equality Comparison on User Defined Formats

Tom — Wed, 25 Sep 2019 19:45:49 GMT

Not sure why are are comparing the strings generated by the format instead of the actual numbers.

But why not just make sure the strings are formatted so they can be compared?

VALUE rvsd_format
   5000-10000="05000-10000"
  10000-25000="10000-25000"
;