topic Re: Problem with my code with macro in New SAS User

Problem with my code with macro

owenwqp1 — Tue, 23 Oct 2018 05:06:08 GMT

Hi,

I use the posted code to generate new vars, but after running the code, I just got one new variable, y20, what's wrong with my code?

Thanks a lot!

%macro abc;
    %do i=1 %to 20;
    data code1;
        set code;
        y&i=x&i/2;
    run;
    %end;
    %mend;
%abc

Re: Problem with my code with macro

Kurt_Bremser — Tue, 23 Oct 2018 05:31:28 GMT

You always overwrite dataset code1, so only the results of the last macro iteration take effect.

Re: Problem with my code with macro

owenwqp1 — Tue, 23 Oct 2018 06:07:57 GMT

Thank you so much Kurtbremser!

Re: Problem with my code with macro

RW9 — Tue, 23 Oct 2018 07:53:04 GMT

More importantly, why are you creating 20 datasets for the same data? This uses more disk space, is slower, and is far harder to maintain. I am pretty certain after seeing this type of code a lot, you will then either be merging those datasets, or looping over them using further messy macro code. Don't. You can simply do one step:

data code1 (drop=i);
  set code;
  array y{20} 8.;
  array x{8};   /* assumes it already exists in code */
  do i=1 to 20;
    y{i}=x{i}/2;
  end;
run;

Or you could create a normalised version of the above with each item in a row rather than columns which is a better structure.

Re: Problem with my code with macro

Astounding — Tue, 23 Oct 2018 12:43:38 GMT

It is possible to use macro language to generate 20 assignment statements within the same DATA step. You just need to rearrange the pieces of your program:

%macro abc;
   data code1;
      set code;
      %do i=1 %to 20;
          y&i=x&i/2;
      %end;
   run;
%mend abc;
%abc