topic Re: Assigning variables in New SAS User

Assigning variables

SASPhile — Thu, 22 Aug 2019 17:38:18 GMT

Hi All,

I have a dataset with same variables starting with underscore and without underscore. I would want to assign (in a loop)all underscore varaibles to those without undsrscore. can you help me on this?

For eg.

_id id _name name

hardcoding I can do this way:

_id=id;

_name=name;

Re: Assigning variables

r_behata — Thu, 22 Aug 2019 18:19:01 GMT

data have;
	_id='   ';
	id='abc';
	_name='   ';
	name='xyz';
	output;
run;

data want;
	set have;
	array ch[*] _character_;

	do i=1 to dim(ch);
		if   find( vname(ch[i]), '_') then
			ch[i]=vvaluex(compress(vname(ch[i]),'_'));
	end;

	drop i;
run;

Re: Assigning variables

FreelanceReinh — Thu, 22 Aug 2019 18:24:57 GMT

Hi @SASPhile,

You could create the repetitive code, e.g., by PROC SQL:

proc sql noprint;
select catx('=',name,substr(name,2)) into :assign separated by '; ' 
from dictionary.columns
where libname='WORK' & memname='HAVE' & name eqt '_';
quit;

data want;
set have;
&assign;
run;

Re: Assigning variables

ballardw — Thu, 22 Aug 2019 18:36:36 GMT

Do your really want to create another set of variables with the same values?

Or do you really need to just Rename the ones that you have, such as for combining with another data set?

If you use the Search bar at the top of your message for something like "Rename all Variables" you find a number of variations on that:

Such as https://communities.sas.com/t5/New-SAS-User/rename-a-whole-set-of-variable-adding-the-same-suffix-to-all-of/m-p/575358#M12845

Your code example assigns the non_underscored variable value to an underscored name. That doesn't quite match your verbiage.

Something like this may work:

%macro dummy;
Proc sql;
   select name into : varlist separated by " "
   from dictionary.columns
   where libname='WORK' and memname='HAVE'
      and substr(name,1,1)='_'
   ;
quit;

data work.want;
   set work.have;
   %do i= 1 %to %sysfunc(countw(&varlist.));
      %let var = %substr(%scan(&varlist., &i),2);
      _&var.= &var.;
     /* or &var. = _&var.; depending on actual direction*/
   %end;
run;
 
%mend;

Which does assume that you have both Name and _Name for all the variables.