topic Re: Default date values to end of month in New SAS User

Default date values to end of month

PSU_Sudzi — Tue, 20 Aug 2019 16:02:42 GMT

Hi Folks,

I have a piece of code that I use (below) to default missing days from partial dates to the first of the month when appropriate but in this case I need to default the missing days to the end of the month, which seems more complicated to a novice like me since the last day of the month can vary. Any ideas how to proceed?

/* month and year entered, default to start of month */

if substr(eoslvdat,1,1) = '-' and substr(eoslvdat,3,1) ne '-' then eoslvdtn=input(trim('01')||substr(eoslvdat,3),date9.)

data WORK.EOS;
  infile datalines dsd truncover;
  input _usubjid:$6. eoslvdat:$9.;
  label _usubjid="Unique Subject Identifier" eoslvdat="Date of last visit";
datalines;
01/001 25APR2019
01/002 02MAY2019
01/003 08OCT2018
01/004 15NOV2018
01/005 12JUN2018
01/006 06JUN2019
01/007 --DEC2018
;;;;

Re: Default date values to end of month

Reeza — Tue, 20 Aug 2019 16:11:09 GMT

Convert them to SAS dates and then use INTNX to set to the end of the month.

1. Use TRANSLATE to convert the -- to 01
I'll leave that to you. Do you have more than missing days you need to account for? You can use the code you already have to put it as 01.
2. Convert to SAS date using INPUT()
new_var = input(eoslvdat, date9.);
3. Change to end of the month
new_var = intnx('month', new_var, 0, 'e');

Re: Default date values to end of month

novinosrin — Tue, 20 Aug 2019 16:20:37 GMT



data WORK.EOS;
  infile datalines  dlm=' ' truncover;
  input _usubjid:$6. eoslvdat :$9.;
  label _usubjid="Unique Subject Identifier" eoslvdat="Date of last visit";
datalines;
01/001 25APR2019
01/002 02MAY2019
01/003 08OCT2018
01/004 15NOV2018
01/005 12JUN2018
01/006 06JUN2019
01/007   DEC2018
;;;;

data want;
set eos;
want=input(eoslvdat,?? date9.);
if want=. then want=intnx('mon',input(cats('01',eoslvdat),date9.),0,'e');
format want date9.;
run;

And suppose you have full missing values for your eoslvdat variable, the above is modified to

data want;
set eos;
if not missing(eoslvdat) then do;
want=input(eoslvdat,?? date9.);
if want=. then want=intnx('mon',input(cats('01',eoslvdat),date9.),0,'e');
end;
format want date9.;
run;

Re: Default date values to end of month

PSU_Sudzi — Tue, 20 Aug 2019 16:20:44 GMT

Thanks for the response Reeza. In this dataset I only need to account for missing days, not months or years as I might in others. I hadn't thought of converting the -- to 01 and then using INTNX, but that seems like a good idea!

Re: Default date values to end of month

PSU_Sudzi — Tue, 20 Aug 2019 16:22:46 GMT

Thank you Novinosrin, this also seems like it would work, will give it a shot too!