topic Macro variable not resolving as per the need...!!! file_cnt in New SAS User

Macro variable not resolving as per the need...!!! file_cnt

prad001 — Mon, 12 Aug 2019 16:08:19 GMT

Hi All,

I am trying to put the value of 'i' in a macro within a data step using call symput. When csv_name is resolving accurately with the value of i, then why not file_cnt ? Please let me know where did i go wrong or show me a way of how to rewrite this query more efficiently. Help appreciated..

Thanks alot.

%let num=100;

DATA new1;

do new=1 to 1000; output;end;

run;

proc sort data=new1;by new;run;

data new2;

set new1;

by new;

IF _n_=1 THEN do;

i=1;

j=0;

END;

RETAIN i j;

IF j=100 then do;

i=i+j;

j=0;

END;

********************************************************

In this block I am creating names for the csv dividing them into 100 records / csv

******************************************************;

IF NEW >= i and NEW <= (i+&num-1) THEN DO;

csv_name=i;

call symput('file_cnt',put(i,3.));

******************************************************
Below is the file_cnt which is not resolving as per the need
******************************************************;

file = "abc_&file_cnt._dt.csv";

END;

IF First.NEW THEN DO;

j=j+1;

csv=i;

ENd;

run;

Re: Macro variable not resolving as per the need...!!! file_cnt

Tom — Mon, 12 Aug 2019 16:15:47 GMT

I cannot make sense of your logic, but your error with respect to macro variables is clear.

When the data step is compiled this statement is evaluated:

file = "abc_&file_cnt._dt.csv";

And turned into something like:

file = "abc_123_dt.csv";

Then later when the data step is running this line will execute

call symput('file_cnt',put(i,3.));

and set a value for FILE_CNT that you could use in the NEXT block of SAS code that you want to generate.

If you want the value of FILE to be based on the value of I then tell SAS to build it using I and not some macro variable.

file = cats('abc_',put(i,Z3.),'_dt.csv');

Re: Macro variable not resolving as per the need...!!! file_cnt

novinosrin — Mon, 12 Aug 2019 16:24:22 GMT

I can't make sense of the logic here. But methinks resolve is what you are after. is this what you are after by any chance?

file = resolve('abc_&file_cnt._dt.csv');

So, if yes



%let num=100;

DATA new1;
do new=1 to 1000; output;end;
run;
proc sort data=new1;by new;run;
 
data new2;
set new1;
by new;
 
IF _n_=1 THEN do; 
  i=1;
j=0; 
END;
 
RETAIN i j;
 
IF j=100 then do;
i=i+j; 
j=0;
END;
 
********************************************************
In this block I am creating names for the csv dividing them into 100 records / csv
******************************************************;
 
 
IF NEW >= i and NEW <= (i+&num-1) THEN DO;
csv_name=i;
call symputx('file_cnt',put(i,3.));
******************************************************
Below is the file_cnt which is not resolving as per the need
******************************************************;
file = resolve('abc_&file_cnt._dt.csv');
END;
 
 
 
IF First.NEW THEN DO;
j=j+1;
csv=i;
ENd;
run;