topic Re: INTNX for week day in %SYSFUNC in New SAS User

INTNX for week day in %SYSFUNC

sivastat08 — Fri, 12 Jul 2019 10:45:06 GMT

Hi ,

I am trying to create monday and friday using sysfunc in sas EG but its not working for me.Kindly help me on below code.

%LET Monday = %SYSFUNC(INTNX('WEEK.2',%SYSFUNC(TODAY()),2),DOWNAME.);
%PUT &Monday;
%LET Friday = %SYSFUNC(INTNX('WEEK.6',%SYSFUNC(TODAY()),6),DOWNAME.);
%PUT &Friday;

Thanks,

Siva

Re: INTNX for week day in %SYSFUNC

PeterClemmensen — Fri, 12 Jul 2019 11:08:45 GMT

Small changes

%LET Monday = %SYSFUNC(INTNX(WEEK.2,%SYSFUNC(TODAY()),0), 'b');
%PUT &Monday;
%LET Friday = %SYSFUNC(INTNX(WEEK.6,%SYSFUNC(TODAY()),0), 'b');
%PUT &Friday;

Re: INTNX for week day in %SYSFUNC

sivastat08 — Fri, 12 Jul 2019 11:14:59 GMT

Hello Sir, Thanks for the answer, Code ae working fine but Format is not showing Monday or Friday
26 GOPTIONS ACCESSIBLE;
27 %LET Monday = %SYSFUNC(INTNX(WEEK.2,%SYSFUNC(TODAY()),0), 'b');
28 %PUT &Monday;
21738
29 %LET Friday = %SYSFUNC(INTNX(WEEK.6,%SYSFUNC(TODAY()),0), 'b');
30 %PUT &Friday;
21742

,Kindly help me on format

Re: INTNX for week day in %SYSFUNC

PeterClemmensen — Fri, 12 Jul 2019 11:21:30 GMT

What is the Purpose of this? Are you going to use the actual date variables or do you simply want to print 'Monday' and 'Friday' in the log?

Re: INTNX for week day in %SYSFUNC

sivastat08 — Fri, 12 Jul 2019 11:38:11 GMT

I want to send automated email using email body mentioning monday date and friday date as "08Mon19 - 16Fri19"

Re: INTNX for week day in %SYSFUNC

PeterClemmensen — Fri, 12 Jul 2019 11:38:54 GMT

So the real task is to get the string "08Mon19 - 16Mon19" into a macro variable?

Re: INTNX for week day in %SYSFUNC

sivastat08 — Fri, 12 Jul 2019 11:42:41 GMT

Yes sir.This code will run on every friday it should display Current Week Monday to Friday date Dynamically.

Re: INTNX for week day in %SYSFUNC

sivastat08 — Fri, 12 Jul 2019 11:52:46 GMT

here is the sample code

%LET TODAY=%SYSFUNC(TODAY(),DATE9.);
%PUT &TODAY;

%LET Monday = %SYSFUNC(INTNX(WEEK.2,%SYSFUNC(TODAY()),0), 'b');
%PUT &Monday DOWNAME.;
%LET Friday = %SYSFUNC(INTNX(WEEK.6,%SYSFUNC(TODAY()),0), 'b');
%PUT &Friday;

filename outbox email
to= ('XXX.YYY@abchealth.com')
cc= ('sivakumar.siva@abchealth.com')
type='text/html'
subject="Weekly Status";
data _null_;
file outbox;
put "Hi all";
put "<P>";
Put "Please find the Weekly Status Report of 08July2019 - 12jul2019 ";
put "<P>";
put "Thank you,";
run;

Re: INTNX for week day in %SYSFUNC

Tom — Fri, 12 Jul 2019 12:18:52 GMT

@sivastat08 wrote:

I want to send automated email using email body mentioning monday date and friday date as "08Mon19 - 16Fri19"

Then why are you making it harder by trying to do it in macro code? Just do it in a data step and eliminate a lot of complexity.

Re: INTNX for week day in %SYSFUNC

Tom — Fri, 12 Jul 2019 12:24:07 GMT

No need for messing with macro variables if you are already running a data step.

data _null_;
  file outbox;
  monday=intnx('week.2',today(),0);
  friday=monday+4;
  put 'Hi all';
  put '<P>';
  put 'Please find the Weekly Status Report of ' monday date9. ' - ' friday date9.;
  put '<P>';
  put 'Thank you,';
run;

Re: INTNX for week day in %SYSFUNC

sivastat08 — Fri, 12 Jul 2019 13:01:48 GMT

Sure Tom.Thank you for such a detailed answer!