topic Re: how to recode the values of a variable in New SAS User

how to recode the values of a variable

srikanthyadav44 — Fri, 05 Jul 2019 09:00:28 GMT

i have a data of 5000 companies which are repeated for multiple number of times.

I want to code each company as comp1, comp2, comp3 etc.,

the sample of the file is as follows

company

the desired output should be like this

company	code
a	comp1
a	comp1
a	comp1
a	comp1
a	comp1
b	comp2
b	comp2
b	comp2
b	comp2
b	comp2
c	comp3
c	comp3
c	comp3
c	comp3
c	comp3

thanks in advance

Re: how to recode the values of a variable

Kurt_Bremser — Fri, 05 Jul 2019 09:08:01 GMT

Use a retained variable:

data want;
set have;
by company;
retain comp_count 0;
if first.company then comp_count + 1;
code = cats('comp',comp_count);
drop comp_count;
run;

Re: how to recode the values of a variable

novinosrin — Fri, 05 Jul 2019 12:00:58 GMT


data have;
input company $;
cards;
a
a
a
a
a
b
b
b
b
b
c
c
c
c
c
;

data want;
do until(last.company);
set have;
by company;
length code $10;
code=cats('COMP',_n_);
output;
end;
run;

Re: how to recode the values of a variable

Astounding — Fri, 05 Jul 2019 13:06:40 GMT

A good idea, but it can be done with a slightly quicker program:

data want;
length code $ 10;
code = cats('comp', _n_);
do until (last.company);
   set have;
   by company;
   output;
end;
run;