topic Re: how to provide conditional formatting in cell in proc report in sas in New SAS User

how to provide conditional formatting in cell in proc report in sas

sivastat08 — Thu, 20 Jun 2019 10:59:50 GMT

how to provide conditional formatting in cell in proc report in sas

PROC SQL INOBS=100;
CREATE TABLE WORK.QUERY_FOR_CARS AS
SELECT t1.Make,
t1.Model,
t1.Type,
t1.Origin,
t1.DriveTrain,
t1.MSRP,
t1.Invoice,
t1.EngineSize,
t1.Cylinders,
t1.Horsepower,
t1.MPG_City,
t1.MPG_Highway,
t1.Weight,
t1.Wheelbase,
t1.Length
FROM SASHELP.CARS t1;
QUIT;

proc report data=work.query_for_cars;
title HEIGHT=.25in 'Second Level Audit Findings by Client and Auditor' bold;
column Cylinders DriveTrain EngineSize Horsepower Invoice ;
define Cylinders/center;
define DriveTrain/center;
define EngineSize/center;
compute EngineSize;
if EngineSize < 3 then
call define(_col_,"style","style={background=red}");
endcomp;
run;

this report shows red highlighter for column.i need EngineSize < 3 should be red color

Re: how to provide conditional formatting in cell in proc report in sas

ballardw — Thu, 20 Jun 2019 15:11:07 GMT

Sometimes you have to be careful with the DEFINE. Numeric variables will default to SUM analysis and that does not appear to be how you are using Enginesize.

proc report data=work.query_for_cars;
title HEIGHT=.25in 'Second Level Audit Findings by Client and Auditor' bold;
column Cylinders DriveTrain EngineSize Horsepower Invoice ;
define Cylinders/center;
define DriveTrain/center;
define EngineSize/center display;
compute EngineSize;
   if EngineSize < 3 then
   call define(_col_,"style","style={background=red}");
endcomp;
run;

Re: how to provide conditional formatting in cell in proc report in sas

sivastat08 — Fri, 21 Jun 2019 10:31:37 GMT

Thanks for the answer clear explanation Sir.