topic Re: Adding numbers separated by a comma in New SAS User

Adding numbers separated by a comma

amanjot_42 — Wed, 12 Jun 2019 11:42:32 GMT

Hi guys,

Can you please help me in adding up two numbers which are separated by a comma:

Year dividend

2010 10

2011 11,15

2012 16

2013 20

In the example, I want to take the total of 11 and 15 as my final amount for the year 2011.

Regards,

Amanjot

Re: Adding numbers separated by a comma

Kurt_Bremser — Wed, 12 Jun 2019 11:46:55 GMT

So you have a string containing numbers, right? See this:

data have;
input year dividend $;
datalines;
2010 10
2011 11,15
2012 16
2013 20
;

data want;
set have;
do i = 1 to countw(dividend,',');
  div_num = sum(div_num,input(scan(dividend,i,','),best32.));
end;
drop i;
run;

proc print data=want noobs;
run;

Result:

year    dividend    div_num

2010     10            10  
2011     11,15         26  
2012     16            16  
2013     20            20

Re: Adding numbers separated by a comma

amanjot_42 — Wed, 12 Jun 2019 11:57:17 GMT

Thanks, that was so quick!

It worked well

cheers

Re: Adding numbers separated by a comma

amanjot_42 — Wed, 12 Jun 2019 11:57:17 GMT

Thanks, that was so quick!