topic Re: Second Maximum Values in given Dataset in New SAS User

Second Maximum Values in given Dataset

BrahmanandaRao — Tue, 14 May 2019 07:22:39 GMT

Hi Guys,

Good Morning

i have data set below

/*how to find out second max number in sas by using data step*/
data second;
input name$ number;
cards;
aravind 98
kiran 49
lahari 58
ahalya 97
amith 69
ankit 97
abhhi 70
;
run;

in the above data set i want second maximum numbers here observe second max numbers are 97 two times

I want output like below

Name Number

ahalya 97

ankit 97

Re: Second Maximum Values in given Dataset

PeterClemmensen — Tue, 14 May 2019 07:30:22 GMT

Why do you want to do this with a data step? Seems easier with eg PROC RANK like this?

proc rank
    data=second
    ties=dense descending
    out=want(where=(rank=2))
    ;
  var number;
  ranks rank;
run;

Re: Second Maximum Values in given Dataset

BrahmanandaRao — Tue, 14 May 2019 07:35:01 GMT

Hi Dray cut

Thanks for your supporting

But i want output in data step only not in proc step

Regards,

Anand

Re: Second Maximum Values in given Dataset

PeterClemmensen — Tue, 14 May 2019 07:45:53 GMT

Ok. Use a double DoW loop like this then.

data want(drop=_:);

   do until (lr1);
      set second end=lr1;
      if number gt _1 then _1=number;
      if (number lt _1) & (number ge _2) then _2=number;
   end;

   do until (lr2);
      set second end=lr2;
      if number=_2 then output;
   end;

run;

Re: Second Maximum Values in given Dataset

BrahmanandaRao — Tue, 14 May 2019 07:48:10 GMT

data second; input name$ number; cards; aravind 98 kiran 49 lahari 58 ahalya 97 amith 69 ankit 97 abhhi 70 ; run; output like below using only datastep not proc step Obs name number rank 1 ahalya 97 2 2 ankit 97

Re: Second Maximum Values in given Dataset

PeterClemmensen — Tue, 14 May 2019 07:49:49 GMT

Please see the code I provided above. Does it work for you?

Re: Second Maximum Values in given Dataset

BrahmanandaRao — Tue, 14 May 2019 07:51:38 GMT

Thank you dray cut

your are brilliant ☺

Re: Second Maximum Values in given Dataset

Ksharp — Tue, 14 May 2019 12:52:23 GMT


data second;
input name$ number;
cards;
aravind 98
kiran 49
lahari 58
ahalya 97
amith 69
ankit 97
abhhi 70
;
run;
proc sort data=second out=temp;
by descending number;
run;
data want;
 set temp;
 by descending number;
 n+first.number;
 if n=2;
run;

Re: Second Maximum Values in given Dataset

novinosrin — Tue, 14 May 2019 13:42:46 GMT

data second;
input name$ number;
cards;
aravind 98
jack 98
kiran 49
lahari 58
ahalya 97
amith 69
ankit 97
abhhi 70
;

data want ;
if _n_=1 then do;
if 0 then set second;
   dcl hash H (dataset:'second',ordered: "d",multidata:'y') ;
   h.definekey  ("number") ;
   h.definedata ("number","name") ;
   h.definedone () ;
   dcl hiter hh('h');
end;
do _n_=1 by 1 while(hh.next()=0);
	if _n_=1 then rc2=number;
	if rc2 ne number then do;
		do while(h.do_over() eq 0);
		output;
		end;
		stop;
	end;
end;
drop rc:;
run;

Re: Second Maximum Values in given Dataset

BrahmanandaRao — Wed, 15 May 2019 07:32:45 GMT

Hi Ksharp

Good Morning ,

Thank your for your support

brilliant code smileyhappy:

Re: Second Maximum Values in given Dataset

BrahmanandaRao — Wed, 15 May 2019 07:36:30 GMT

Thank you dray cut for your solution

Regards,

Anand