topic Re: Moving Average Forecasting in SAS Forecasting and Econometrics

Moving Average Forecasting

Ujjawal — Sat, 23 Sep 2017 19:19:48 GMT

I am trying to calculate forecasted value using moving average. I am getting different result using PROC EXPAND and PROC ARIMA

Proc expand data= data1 out= new_mydata;
convert sales = sales_movave / transformout=(movave 3);
run;

proc arima data=WORK.DATA1 plots=none out=WORK.out0001;
	identify var=Sales;
	estimate p=(1 2 3) ar=(0.3333333333333333 0.3333333333333333 
		0.3333333333333333) noint method=ULS;
	forecast lead=12;
	run;
quit;

Re: Moving Average Forecasting

Reeza — Sun, 24 Sep 2017 01:08:06 GMT

@Ujjawal wrote:

I am trying to calculate forecasted value using moving average. I am getting different result using PROC EXPAND and PROC ARIMA
Proc expand data= data1 out= new_mydata;
convert sales = sales_movave / transformout=(movave 3);
run;

PROC EXPAND doesn't do forecasting.

Re: Moving Average Forecasting

Puwang — Wed, 11 Oct 2017 14:41:15 GMT

In your PROC ARIMA statement, p= and ar= specifies AutoRegressive paramters. If you want to do moving average, you need to use q= and MA=. As follows:

proc arima data=WORK.DATA1 plots=none out=WORK.out0001;
	identify var=Sales;
	estimate Q=(1 2 3) MA=(0.3333333333333333 0.3333333333333333 
		0.3333333333333333) noint method=ULS;
	forecast lead=12;
	run;
quit;

Re: Moving Average Forecasting

alexchien — Wed, 11 Oct 2017 20:06:52 GMT

1. proc expand computes the moving average (movave) as sales_moave_t = (sales_t-2 + sales_t-1 + sales_t)/3. This is probably not you wanted.

2. proc arima gives you exactly what you are looking for but you need to add a few options to make it work. sales_moave_t = (sales_t-3 + sales_t-2 + sales_t-1)/3

the correct syntax should be

proc arima data=WORK.DATA1 plots=none out=WORK.out0001;
	identify var=Sales;
	estimate p=(1 2 3) ar=(0.3333333333333333 0.3333333333333333 
		0.3333333333333333) noint noest nostable method=CLS;
	forecast lead=12;
	run;
quit;

Without noest nostable, proc arima will use the provided ar values as the initial values and try to estimate them. Thus you might end up with something that's not equally weighted moving averages.

hope this helps

alex