Sample 60267: Using an HTML form to provide values for prompted SAS® Stored Processes

wsdabreu — Wed, 08 May 2019 17:45:34 GMT

I'm trying to execute the following sample in VA, but i'm receiving the error: ERROR: File is in use, _WEBOUT . I've tried SAS suggestions but it didn't work, someone has another tip?

The Code:

/* **************************************************************************************
*  Description:  This stored process creates an html form that then calls a Target stored process
*
*  Inputs:   Two parameters are created from the sashelp.class table: Make and Type
*
*  Outputs:  The submist button call the stored process defined in _program
*
*  NOTE:  You must change the path of the target stored process if the target stored 
*         process is located in a different location in the SAS Management Console
*
**************************************************************************************** */


data _null_;
file _webout;
put '<HEAD><TITLE>HTML Form Example Using Streaming Output</TITLE></HEAD>';
put '<FONT face=Arial size=2 COLOR="#000000">&nbsp;<B>HTML Form Example Using Streaming Output</B></FONT>';
put '<BR><BR>';
put '<FORM action="/SASStoredProcess/do">';
put '<INPUT name="_program" type=hidden value="/Shared Data/Stored Processes/Target(StoredProcess)">';
put '<INPUT name=_debug type=hidden value=0>';
run;

/* ************************************************* */
/* Get a list of car MAKES to populate the list with */
/* ************************************************* */
data _null_;
file _webout;
put '<font face=verdana size=-2>&nbsp;Select Car Make:</FONT>';
put '<SELECT NAME=Make SIZE=1 style="font:10pt arial">';
run;

/* create a unique list of car makes */
proc sort data = sashelp.cars out=work.cars (keep=make) nodupkey;
by make;
run;


data _null_; 
file _webout;
length str $200;
set work.cars;
if _n_=1 then str='<OPTION selected value='||strip(make)||'>'||strip(make)||'</OPTION>';
else str='<OPTION value='||strip(make)||'>'||strip(make)||'</OPTION>';
put str;
run;


/* ************************************************* */
/* Get a list of car TYPES to populate the list with */
/* ************************************************* */
data _null_;
file _webout;
put '</Select><br><br>';
put '<font face=verdana size=-2>&nbsp;Select Car Type:</FONT>';
put '<SELECT NAME=type SIZE=1 style="font:10pt arial">';
run;

/* create a unique list of car makes */
proc sort data = sashelp.cars out=work.cars (keep=type) nodupkey;
by type;
run;


data _null_; 
file _webout;
length str $200;
set work.cars;
if _n_=1 then str='<OPTION selected value='||strip(type)||'>'||strip(type)||'</OPTION>';
else str='<OPTION value='||strip(type)||'>'||strip(type)||'</OPTION>';
put str;
run;

data _null_;
file _webout;
put '</select><br><br>';
 put '&nbsp;&nbsp;<INPUT name=B1 type=submit value=Submit>&nbsp;&nbsp;';
put '<INPUT name=B2 type=reset value=Reset>';

put '</FORM>';
put '<BR><BR>';
run;

Re: Sample 60267: Using an HTML form to provide values for prompted SAS® Stored Processes

FredrikE — Wed, 08 May 2019 18:03:37 GMT

Hi!

You need to disable the automatic macros "%STPBEGIN" and "%STPEND" when you use file _webout.

//Fredrik

Re: Sample 60267: Using an HTML form to provide values for prompted SAS® Stored Processes

wsdabreu — Wed, 08 May 2019 18:48:22 GMT

Do you know where is the option to perform this operation? in the "summary" tab when I select "show full sas code" option, there is no way to edit the prompt.

Edit: I found the option it is in the "SAS Code" tab, then press the button "Include code for" and disable the "Stored process macros".

topic Re: Sample 60267: Using an HTML form to provide values for prompted SAS® Stored Processes in Developers

Sample 60267: Using an HTML form to provide values for prompted SAS® Stored Processes

Re: Sample 60267: Using an HTML form to provide values for prompted SAS® Stored Processes

Re: Sample 60267: Using an HTML form to provide values for prompted SAS® Stored Processes