topic Re: Comaparing Macro variables characters with spaces in Developers

Comaparing Macro variables characters with spaces

TimMandell — Mon, 21 May 2018 20:50:49 GMT

Hello,

I have two Macro variables that resolve to sentences when I attempt to compare them the evaluation method sees the first word in the resolved variable as another variable and provides and error as shown below. Thank you in advance for your response.

%do chg = 1 %to &m_ln;

	/*response */
	%if %sysevalf(%superq( &&asp&chg ) ne , boolean)  %then %do;
		%if "%NRBQUOTE(&&asp&chg)" ne "%NRBQUOTE(&&bsp&chg)" %then %do;
		proc sql;
   		update dat.rvw_data 	set auditor = "&usr", Response="%NRBQUOTE(&&asp&chg)", audit_date="&srttm" where id= &&id&chg;
 		quit;
		%end;
	%end;
%end;

/*
where asp&chg  and bsp&chg can resolve to values like

Clean Up your room

The room is clean

New Chore

Old Chore


example error
SYMBOLGEN:  Macro variable ASP1 resolves to Clean Up your room
ERROR: Invalid symbolic variable name CLEAN.
*/

Re: Comaparing Macro variables characters with spaces

Astounding — Mon, 21 May 2018 20:59:03 GMT

If these values are truly representative of your data, it is overkill to use double-quotes around %NRBQUOTE. Most likely the problem is stemming from the SQL code (not the %IF %THEN statement), since SQL is notoriously poor at parsing macro-quoted strings.

You can test the theory seeing if this change runs without error:

Response = "&&asp&chg"

The other %NRBQUOTEs are probably overkill but don't hurt anything.

Re: Comaparing Macro variables characters with spaces

Kurt_Bremser — Tue, 22 May 2018 06:01:51 GMT

And why are you doing this with a list of macro variables instead of a dataset?

Keep in mind that the macro processor is a code generator, not a data handler.

Re: Comaparing Macro variables characters with spaces

TimMandell — Tue, 22 May 2018 13:22:36 GMT

I have an input form using HTML/Javascript and initiated by stored process.

The variables contents to compare are the values obtained from the input form.

It seems very straight forward to compare the variables directly rather then moving the values into a dataset and making comparisons in that manner.

The next step after comparison is for inequalities replace the current value to the new value.

Re: Comaparing Macro variables characters with spaces

Kurt_Bremser — Tue, 22 May 2018 13:41:57 GMT

The fact that you had to come here seeking help should tell you that it is not straight forward at all.

That's because the macro processor is not the right engine for this at all. Once, again, it's a code generator, not meant to deal with data.

Both the data step and proc sql provide simple means for updating one dataset from the other. A check for inequality is not needed, as the update would replace a value with the same value anyway (in case of them being equal), causing no harm.

Getting a list of macro variables into a dataset OTOH IS straight forward:

%let asp1=The room is clean;
%let asp2=The room needs to be cleaned;
%let m_ln=2;

data data_upd;
length response $50;
do chg = 1 to &m_ln;
  response = symget(cats('asp',chg));
  output;
end;
run;

Re: Comaparing Macro variables characters with spaces

Quentin — Tue, 22 May 2018 14:16:22 GMT

Looks to me like the problem is with %SUPERQ. You pass it the name of a macro variable without an & in front, unlike the other quoting functions which get passed a reference to a macro variable with the &.

Also, I don't think %NRBQUOTE is good for anything. I would suggest (untested):

	%if %sysevalf(%superq(asp&chg) ne , boolean)  %then %do;
		%if %BQUOTE(&&asp&chg) ne %BQUOTE(&&bsp&chg) %then %do;
		proc sql;
   		update dat.rvw_data 	set auditor = "&usr", Response="%BQUOTE(&&asp&chg)", audit_date="&srttm" where id= &&id&chg;
 		quit;
		%end;
	%end;

Re: Comaparing Macro variables characters with spaces

TimMandell — Tue, 22 May 2018 14:45:41 GMT

That was it... Was calling the %superq variable incorrectly (using && before first partial variable name).

and %bquote allows for the comparison.

Thank you