topic Re: Proc Export Error: Excel cannot open the file. in Developers

Proc Export Error: Excel cannot open the file.

mrg1212005 — Wed, 06 Sep 2017 19:30:29 GMT

I am trying to create excel spreadsheet via the stored process by using Proc Export. Log suggests that file has been created without any error but when I try to open the file I get this error:

Excel cannot open the file 'myfile.xlsx' because the file format or the file extension is not valid. Verify that the file has not been corrupted or that the file extension matches the format of the file.

I am using following code in my stored process to create spreadsheets.

%if &Output=EXCEL %then %do;
data _null_;
   rc=stpsrv_header('Content-type','application/vnd.ms-excel');
   rc=stpsrv_header('Content-disposition',"attachment; filename=&geosumlvl._&tabname..xlsx");         
run;

proc export data=Extract_ACS outfile=_webout dbms=xlsx replace;
sheet='mysheet';
run;

%end;

I am wondering if we have a solution to resolve this issue?

Re: Proc Export Error: Excel cannot open the file.

SASKiwi — Wed, 06 Sep 2017 20:49:38 GMT

What SAS version are you using? XLSX only became available in 9.4M2. Try XLS also.

Re: Proc Export Error: Excel cannot open the file.

ballardw — Wed, 06 Sep 2017 21:07:50 GMT

Is your Excel 32-bit or 64-bit? The 32-bit versions don't like opening 64-bit files.

Re: Proc Export Error: Excel cannot open the file.

Vince_SAS — Fri, 08 Sep 2017 13:41:08 GMT

I don't think that PROC EXPORT correctly writes to the _WEBOUT FIILEREF, even though no errors are reported.

Try this code and if it works, then you can adapt it to your data:

ods _all_ close;

data _null_;
rc=stpsrv_header('Content-type','application/vnd.ms-excel');
rc=stpsrv_header('Content-disposition',"attachment; filename=Class.xlsx");         
run;

%let WORKPATH=%sysfunc(pathname(work));

filename temp "&WORKPATH/temp.xlsx";

proc export data=sashelp.class 
  outfile=temp 
  dbms=xlsx 
  replace;
  sheet='mysheet';
run; quit;

data _null_;
infile temp recfm=f lrecl=1;
file _webout recfm=n;
input;
put _infile_;
run;

Vince DelGobbo

SAS R&D