Using Boolean parameters in a stored process

Dan_S — Thu, 05 Oct 2006 20:48:58 GMT

I was having some problems getting a SP to work with a Boolean Parameter. I have made up a mock example to simplify my code. It seem that I always return a=1 and b=1 whether my boolean value is true or false? here is my code. Thank you in advance for your help. Dan
%Global b1;

data fun;
a = 0;
b = 0;
data fun;
set fun;
if &b1=true then
do;
a = 1;
b = 1;
end;
proc print;
run;

Re: Using Boolean parameters in a stored process

Olivier — Mon, 16 Oct 2006 12:56:08 GMT

I would think that it's rather a macro logic problem than a stored process problem.
When you write a SAS statement like the IF statement, it is not processed by the macro facility.
Hence what you write is either :

IF true = true THEN DO ; etc.

or

IF false = true THEN DO ; etc.

From a SAS (and not macro) point of view, this means you are comparing values for variables named TRUE or FALSE. Not that you're comparing text strings "TRUE" or "FALSE", which would require quotes around the value itself.
As the variables TRUE and FALSE don't exist in your dataset, they are created with missing values (you should see them in the printed output). Your condition, in every case, ends up as :
IF . = . THEN ...
which is always true.

I would transform your program into :

%Global b1;
data fun;
a = 0;
b = 0;
data fun;
set fun;
if "%UPCASE(&b1)"="TRUE" then
do;
a = 1;
b = 1;
end;
proc print;
run;

another solution is to use the macro-IF, for which everything is just plain text and then, no quotes needed anywhere.

%Global b1;

data fun;
a = 0;
b = 0;
data fun;
set fun;
%if &b1=true %then
%do;
a = 1;
b = 1;
%end;
proc print;
run;

topic Using Boolean parameters in a stored process in Developers

Using Boolean parameters in a stored process

Re: Using Boolean parameters in a stored process