topic Re: How to remove last word of a string in SAS Data Science

How to remove last word of a string

huffa9299 — Wed, 22 Aug 2018 19:30:32 GMT

Hello,

I have a problem that I think should be simple but cannot quite get it to work. I need to remove the last word in a string.

Have:

Obs	Product
1	Product A 1835
2	Product B 201
3	Product A 35
4	Product B 4893

Want:

Obs	Product	Product_Fam
1	Product A 1835	Product A
2	Product B 201	Product B
3	Product A 35	Product A
4	Product B 4893	Product B

is there a simple way to do this?

thank you for your help!

Re: How to remove last word of a string

Reeza — Wed, 22 Aug 2018 19:33:06 GMT

Is it always numbers at the end?

If so, can you apply the COMPRESS() function to the variable to remove the numbers?

productID = compress(product, , 'ka');
Number = compress(product, , 'kd');

Re: How to remove last word of a string

Kurt_Bremser — Wed, 22 Aug 2018 19:35:32 GMT

product = substr(product,1,length(product)-length(scan(product,-1,' ')));

Re: How to remove last word of a string

PeterClemmensen — Wed, 22 Aug 2018 19:39:12 GMT

Like this?

data have;
input Obs Product $50.;
infile datalines dlm=',';
datalines;
1,Product A 1835
2,Product B 201
3,Product A 35
4,Product B 4893
;

data want(drop=pos length);
   set have;
   call scan(Product, -1, pos, length);
   Product_Fam=substr(Product,1,pos-2);
run;

Re: How to remove last word of a string

huffa9299 — Wed, 22 Aug 2018 19:42:15 GMT

Thank you Reeza and Draycut, both worked well, thank you for help!

Re: How to remove last word of a string

novinosrin — Wed, 22 Aug 2018 20:30:31 GMT

Just for fun:

data have;
input Obs Product $50.;
infile datalines dlm=',';
datalines;
1,Product A 1835
2,Product B 201
3,Product A 35
4,Product B 4893
;

data want;
set have;
Product_Fam=substr(Product,1,length(product)-anyspace(reverse(strip(product))));
run;

Re: How to remove last word of a string

ballardw — Wed, 22 Aug 2018 20:59:39 GMT

And another:

data have;
input Obs Product $50.;
infile datalines dlm=',';
datalines;
1,Product A 1835
2,Product B 201
3,Product A 35
4,Product B 4893
;
data want;
set have;
Product_Fam=strip(tranwrd(product,scan(Product,-1),''));
run;

Re: How to remove last word of a string

Ksharp — Thu, 23 Aug 2018 12:42:59 GMT

data have;
input Obs Product $50.;
infile datalines dlm=',';
datalines;
1,Product A 1835
2,Product B 201
3,Product A 35
4,Product B 4893
;

data want;
 set have;
 want=prxchange('s/\w+$//',1,strip(Product));
run;