topic Re: Calculate sensitivity and specificity and K Fold Cross validation - Enterprise Miner in SAS Data Science

Calculate sensitivity and specificity and K Fold Cross validation - Enterprise Miner

dee2017 — Sat, 12 Aug 2017 20:38:50 GMT

Hello,

I am trying to work how to do sensitivity and speciﬁcity in SAS Miner.

Is there a specific setting i should use?

I want to know how to get the information for ANN, DT and Logistic regression.

Also trying to work how I can do K-fold cross validation for the above models.

Please can you help?

Thanks

Dee

Re: Calculate sensitivity and specificity and K Fold Cross validation - Enterprise Miner

Ksharp — Sun, 13 Aug 2017 11:13:16 GMT

The following code I wrote before is for K Fold CV of logistic regression.






/****** K-Fold CV ****/
%macro k_fold_cv(k=10);
ods select none;

proc surveyselect data=sashelp.heart group=&k out=have;
run;

%do i=1 %to &k ;
data training;
 set have(where=(groupid ne &i)) ;
run;
data test;
 set have(where=(groupid eq &i));
run;

ods output 
Association=native(keep=label2 nvalue2 rename=(nvalue2=native) where=(label2='c'))
ScoreFitStat=true(keep=dataset freq auc rename=(auc=true));
proc logistic data=training
 outest=est(keep=_status_ _name_) ;
 class sex;
 model status(event='Alive')=sex height weight;
 score data=test fitstat; 
run;

data score&i;
 merge true native est;
 retain id &i ;
 optimism=native-true;
run;
%end;
data k_fold_cv;
 set score1-score&k;
run;

ods select all;
%mend;

%k_fold_cv(k=10)








/*************************************/


%macro k_fold_cv_rep(r=1,k=10);
ods select none;
%do r=1 %to &r;
proc surveyselect data=sashelp.heart group=&k out=have;
run;

%do i=1 %to &k ;
data training;
 set have(where=(groupid ne &i)) ;
run;
data test;
 set have(where=(groupid eq &i));
run;

ods output 
Association=native(keep=label2 nvalue2 rename=(nvalue2=native) where=(label2='c'))
ScoreFitStat=true(keep=dataset freq auc rename=(auc=true));
proc logistic data=training
 outest=est(keep=_status_ _name_) ;
 class sex;
 model status(event='Alive')=sex height weight;
 score data=test fitstat; 
run;

data score_r&r._&i;
 merge true native est;
 retain rep &r id &i;
 optimism=native-true;
run;
%end;
%end;
data k_fold_cv_rep;
 set score_r:;
run;

ods select all;
%mend;

%k_fold_cv_rep(r=20,k=10);


/********************/
data all;
 set k_fold_cv k_fold_cv_rep indsname=indsn;
 length indsname $ 32;
 indsname=indsn;
run;
proc summary data=all nway;
 class indsname;
 var optimism;
 output out=want mean=mean lclm=lclm uclm=uclm;
run;

Re: Calculate sensitivity and specificity and K Fold Cross validation - Enterprise Miner

dee2017 — Sun, 13 Aug 2017 16:04:09 GMT

Thanks very much for the reply.

But is there anything that can be done by setting the properties in sas miner i.e. using the GUI rather than coding?

Not very confident with sas coding at the moment.

Re: Calculate sensitivity and specificity and K Fold Cross validation - Enterprise Miner

Ksharp — Mon, 14 Aug 2017 12:12:38 GMT

Sorry. I don't have much experience with EM .

Re: Calculate sensitivity and specificity and K Fold Cross validation - Enterprise Miner

dee2017 — Mon, 14 Aug 2017 23:21:04 GMT

okay thanks anyway