topic Retain original format and label after renaming variables in SAS Data Management

Retain original format and label after renaming variables

Miracle — Fri, 27 Jan 2017 04:16:08 GMT

Hi there.

I used the macro %macro replaceprefix(lib,dsn,start,end,oldprefix,newprefix); to perform the prefix addition on selected variables and it is accesible from http://support.sas.com/resources/papers/proceedings09/075-2009.pdf. However, it doesn't retain the format and label of the variables.

Can I please ask your help to shed some lights on this? Thank you very much.

Re: Retain original format and label after renaming variables

ankit___gupta — Fri, 27 Jan 2017 07:32:51 GMT

Hi Wong,

Why don't you set the format and label once more after the renaming.

In the %macro replaceprefix(lib,dsn,start,end,oldprefix,newprefix); try adding the following.

DATA    <lib>.<datasetname>;
    SET <lib>.<datasetname>;
        FORMAT <variable name> <format>;
	INFORMAT  <variable name> <format>;
        LABEL <label u want to give>;
RUN;

Hope it helps.

Re: Retain original format and label after renaming variables

Astounding — Fri, 27 Jan 2017 12:16:50 GMT

Shed some light? Yes. Fix? No.

You'll have to inspect the details within the macro you referenced. It uses a DATA step to copy the original variables to new variables (then subsequently drops the original variables). When you do that, formats and labels do not get copied, just the data values.

There are other macros within the paper that don't do that, using PROC DATASETS instead of a DATA step. But those macros don't perform the exact same function as the one you are using.

Re: Retain original format and label after renaming variables

Miracle — Fri, 27 Jan 2017 16:14:34 GMT

Problem's now solved after adding a few lines of SAS statements to the macro.

Thank you

Re: Retain original format and label after renaming variables

ankit___gupta — Sat, 28 Jan 2017 02:53:42 GMT

Hi wong ,

So what was the solution ? Can u share ?

Re: Retain original format and label after renaming variables

Miracle — Sat, 28 Jan 2017 13:58:39 GMT

Hi @ankit___gupta,

Please find modified SAS code below (last 2 %let statements within the first do loop, label and format statement in the second datastep).

HTH. Thank you.

/*
Paper 075-2009
Renaming in Batches
Vincent Weng, Educational Testing Service, Princeton, NJ
Ying Feng, CTB/McGraw-Hill, Monterey, CA 

accessible via http://support.sas.com/resources/papers/proceedings09/075-2009.pdf
*/

/* Replacing Prefix on Selected Variables */
%macro replaceprefix(lib,dsn,start,end,oldprefix,newprefix);
proc contents data=&lib..&dsn.; title 'before renaming'; run;
data temp; set &lib..&dsn.; run;
%LET ds=%SYSFUNC(OPEN(temp,i));
%LET ol=%LENGTH(&oldprefix.);
%DO i=&start %TO &end;
	%LET dsvn&i=%SYSFUNC(VARNAME(&ds,&i));
	%LET l=%LENGTH(&&dsvn&i);
	%LET vn&i=&newprefix.%SUBSTR(&&dsvn&i,&ol+1,%EVAL(&l-&ol));

	%LET dsvnlab&i=%BQUOTE(%SYSFUNC(VARLABEL(&ds,%SYSFUNC(varnum(&ds,&&dsvn&i)))));
	%LET dsvnfmt&i=%SYSFUNC(VARFMT(&ds,%SYSFUNC(varnum(&ds,&&dsvn&i))));

%end;
data &lib..&dsn.;
	set temp;

	%DO i=&start %TO &end; 
		&&vn&i=&&dsvn&i; 
		label &&vn&i=%STR(&&dsvnlab&i);
		format &&vn&i &&dsvnfmt&i.;
		drop &&dsvn&i; 
	%end;
	%let rc=%SYSFUNC(CLOSE(&ds));
	proc contents data=&lib..&dsn.;
	title 'Replacing Prefix on Selected variables ';
run;
%mend replaceprefix;