topic Random id for same mother in SAS Data Management

Random id for same mother

malena — Fri, 26 Feb 2016 21:41:11 GMT

Hello,

I am trying to assign a random id to mothers in a dataset for 4 years. Of course there are many mothers who give birth more than once in this dataset so I will like to use the same random id if that is the case. I have close to 200,000 records and a key using last name, first name and DOB of the mothers.

thanks!

Random id for same mother

malena — Fri, 26 Feb 2016 21:48:09 GMT

Hello,

thanks!

Re: Random id for same mother

LinusH — Fri, 26 Feb 2016 22:57:41 GMT

What will be the use of the random id?

Re: Random id for same mother

TomKari — Sat, 27 Feb 2016 03:33:21 GMT

People frequently use UUIDs for this. Check out the UUIDGEN function.

Tom

Re: Random id for same mother

PGStats — Sat, 27 Feb 2016 03:46:51 GMT

To get random ids going from 1 to the number of distinct mothers, do:

proc sort data=mothers; by lastName firstName dob; run;

data mothers2;
call streaminit(7568);
retain id;
set mothers; by lastName firstName dob;
if first.dob then id = rand("UNIFORM");
run;

proc rank data=mothers2 out=mothersId ties=dense;
var id;
run;

(untested)

Re: Random id for same mother

Ksharp — Sat, 27 Feb 2016 03:55:04 GMT

Hash Table

data have;
input first $ last $ dob : date9.;
format dob date9.;
cards;
a b 03jun1991
b c 09jan1980
b c 09jan1980
a b 03jun1991
;
run;
data want;
 if _n_=1 then do;
  if 0 then set have;
  declare hash h();
  h.definekey('first','last','dob');
  h.definedata('id');
  h.definedone();
 end;
 set have;
 rc=h.find();
 if rc ne 0 then do;n+1;id=n;h.add();end;
 drop rc n;
run;

Re: Random id for same mother

PGStats — Sat, 27 Feb 2016 04:49:55 GMT

Or, if you just want large non repeating numbers as ids :

proc sort data=mothers; by lastName firstName dob; run;

data mothersId;
call streaminit(7566);
retain id;
set mothers; by lastName firstName dob;
if first.dob then id = int(1e12*rand("UNIFORM"));
format id z12.0;
run;

Re: Random id for same mother

LinusH — Sat, 27 Feb 2016 06:36:40 GMT

Not knowing the use case, but perhaps hashing the concatenated business key values could be one solution.
The id values will distributed, it's quite safe if privacy is required and it's simple to use: given the same input always the same hash is produced. Check out the md5() function.

Re: Random id for same mother

Reeza — Sat, 27 Feb 2016 18:23:20 GMT

Hashing isn't a good idea...

New York Taxi Open Data - Reversed Engineered

http://www.theguardian.com/technology/2014/jun/27/new-york-taxi-details-anonymised-data-researchers-warn

Re: Random id for same mother

malena — Mon, 29 Feb 2016 14:27:21 GMT

thank you! this works perfectly