topic Re: data is cut off because it is too long in a row in SAS Data Management

data is cut off because it is too long in a row

wutao9999 — Sat, 09 Jan 2016 23:44:20 GMT

For the data in the attached file, I used the below code to repull the data. However, the data has been cut off in the middle because the data in a row is too long. Is there a way to set some number such that the data is not cut off? Thank you for the help.

data want ;

length filename fn $200 ;

infile 'C:\Users\*.txt' filename=fn eov=eov length=ll column=cc truncover ;

fileno+1;

do row=1 by 1 until (eov) ;

do col=1 by 1 until (cc>ll);

input num @ ;

filename=fn ;

output;

end;

input;

end;

run;

Re: data is cut off because it is too long in a row

Reeza — Sun, 10 Jan 2016 00:16:06 GMT

RTM - LRECL on Infile

https://support.sas.com/documentation/cdl/en/lestmtsref/68024/HTML/default/viewer.htm#n1rill4udj0tfun1fvce3j401plo.htm

Re: data is cut off because it is too long in a row

PGStats — Sun, 10 Jan 2016 04:37:28 GMT

... Also, the eov variable is set to 1 after you read a line from the next file and it is not reset by SAS. Try this logic:

data test;
length fn filename $200;
infile "C:\users\*.txt" filename=fn eov=eov 
    length=ll column=cc truncover lrecl=2000;
input @; /* Read a line to trigger eov */
if eov then do;
    fileno + 1;
    row = 0;
    eov = 0; /* reset eov */
    end;
row + 1;
filename = fn;
do col = 1 by 1 until(cc>ll);
    input num @;
    output;
    end;
run;

Re: data is cut off because it is too long in a row

PGStats — Sun, 10 Jan 2016 04:48:03 GMT

Note: The default LRECL under Windows was increased in SAS 9.4 to 32767 . OP is probably running an earlier version where the default LRECL under Windows was 256.

http://support.sas.com/documentation/cdl/en/hostwin/63047/HTML/default/viewer.htm#chifoptfmain.htm