topic Re: help needed with import of text file using infile in SAS Data Management

help needed with import of text file using infile

venkatnaveen — Sun, 05 Apr 2015 19:31:58 GMT

I tried the below code

But i am not getting the. result.I need some help.Is there any other method.help me out please

DATA Sara2013;

INFORMAT Date YYMMDD10. Time $5. ;

FORMAT Date YYMMDD10. Time $5. ;

INFILE 'C:\nav\2013_Satisfaction_Survey_Sara (4).txt'

LRECL=32767 dsd dlm='' truncover firstobs=2;

INPUT @1 Date: YYMMDD10. @12 Time : $5.

@18 Interviewer :$4. @23 Age :$2. @26 Gender :$1. @28 Address: &$18. @48 FirstTime :$6. @52 ComeAgain :$5. WhyNot: $11. (Sat1-Sat8)(:$3.) Comments :$50.;

;

RUN;

Re: help needed with import of text file using infile

art297 — Sun, 05 Apr 2015 21:18:20 GMT

The following worked for me:

DATA Sara2013;

INFILE 'C:\temp\2013_Satisfaction_Survey_Sara (2).txt'

LRECL=32767 termstr=LF truncover firstobs=2;

informat date yymmdd10.;

informat time $5.;

informat interviewer $4.;

informat age $2.;

informat gender $1.;

informat address $18.;

informat FirstTime $3.;

informat ComeAgain $3.;

informat WhyNot $11.;

informat Sat1-Sat7 $3.;

informat Sat8 $2.;

informat Comments $50.;

FORMAT Date YYMMDD10. Time $5. ;

INPUT @1 Date Time 12-16

Interviewer 18-21 Age 23-24 Gender 26-26 Address 28-46

FirstTime 48-50 ComeAgain 52-54 WhyNot 56-66

Sat1 68-70 Sat2 72-74 Sat3 76-78 Sat4 80-82

Sat5 84-86 Sat6 88-90 Sat7 92-94 Sat8 96-97 Comments 98-147;

;

RUN;

Re: help needed with import of text file using infile

Tom — Mon, 06 Apr 2015 00:56:40 GMT

You probably need to add the TRUNCOVER option to the INFILE statement since some of the lines appear shorter than others.

Also you need to add the FIRSTOBS=2 option to get it to skip the header line in the file.

Re: help needed with import of text file using infile

venkatnaveen — Mon, 06 Apr 2015 03:29:39 GMT

Thanks Arthur.But,what is trmstr='lF' option and why individually writing of informat statement .cant we mention with a colon modifier :

Re: help needed with import of text file using infile

art297 — Mon, 06 Apr 2015 12:35:28 GMT

termstr=LF is to indicate that your records end with '10'x (line feed) character, rather that the combination of a CR and a line feed.

While I don't know how common it is, I have always liked defining informats rather than specifying them in the input statement and using colons. Obviously, you could try alternative approaches, but the one I suggested appears to correctly read your file.