topic Re: conditionally deleting part of an entry in SAS Data Management

conditionally deleting part of an entry

ilikesas — Sun, 03 May 2015 20:19:58 GMT

Hi,

suppose I have the following entries:

entry
1234510
8765420
457BH10
6g338k

What I would like to get is the following: if the last 2 characters of the entry are either 10 or 20, then delete these two characters so that the final result is like this:

entry
12345
87654
457BH
6g338k

thank you!

Re: conditionally deleting part of an entry

Patrick — Sun, 03 May 2015 20:44:16 GMT

data sample;

input string $;

length want $8;

want=prxchange('s/([12]0)[[:blank:]]*$//o',1,string);

datalines;

1234510

8765420

457BH10

6g338k

;

run;

Re: conditionally deleting part of an entry

stat_sas — Sun, 03 May 2015 21:20:21 GMT

data want;

set have;

if substr(entry,length(entry)-1) in ('10','20') then entry=substr(entry,1,length(entry)-2);

run;

Re: conditionally deleting part of an entry

ilikesas — Mon, 04 May 2015 05:24:56 GMT

hi sas@stat,

I ran your code but unfortunately the new "entry" column was all empty ...

Re: conditionally deleting part of an entry

ilikesas — Mon, 04 May 2015 05:26:22 GMT

Hi Patrick,

ran your code and got the result that I wanted.

I was just wandering, is it possible to generalize your code so that it can delete any given last numbers?

Re: conditionally deleting part of an entry

LinusH — Mon, 04 May 2015 07:47:20 GMT

You could embed it in a user defined function (PROC FCMP), and thus make it easy to send parameters.

Re: conditionally deleting part of an entry

Patrick — Mon, 04 May 2015 08:28:55 GMT

I guess we would need to generate the Regular Expression but if it's as simple as just a list of a few digits then this shouldn't be too hard.

Some code like below would do:

data list;

length str $3;

str='10';output;

str='20';output;

str='38k';output;

stop;

run;

proc sql noprint;

select strip(str) into :rem_list separated by '|'

from list

;

quit;

%put rem_list: &rem_list;

data sample;

input string $;

length want $8;

want=prxchange("s/(&rem_list)[[:blank:]]*$//o",1,string);

datalines;

1234510

8765420

457BH10

457BH30

6g338k

;

run;

Re: conditionally deleting part of an entry

Kurt_Bremser — Mon, 04 May 2015 10:54:33 GMT

You must have made an error, look at the log.

This code:

data have;

infile cards;

input entry: $7.;

cards;

1234510

8765420

457BH10

6g338k

;

run;

data want;

set have;

if substr(entry,length(entry)-1) in ('10','20') then entry=substr(entry,1,length(entry)-2);

run;

proc print data=have;

proc print data=want;

run;

gives this result:

Obs

entry

1	1234510
2	8765420
3	457BH10
4	6g338k

Obs

entry

1	12345
2	87654
3	457BH
4	6g338k

Re: conditionally deleting part of an entry

stat_sas — Mon, 04 May 2015 11:23:09 GMT

Hi,

Please check it again as mentioned above. This works for me.