topic Re: Char to Numeric with Date Format in SAS Data Management

Char to Numeric with Date Format

danimian — Wed, 18 Jun 2014 16:00:10 GMT

Hello,

i have a field date_in with data type character with value for example '15.04.2014 10:15' (DD.MM.YYY HH:MM)

Target field date_out has numeric type.

Is there any SAS date format which match with this format?

or how i can deliver the date in above format?

I just tried some formats with input(date_in, format) but cannot find the wanted format result.

Thanks for your support in advance

Re: Char to Numeric with Date Format

Haikuo — Wed, 18 Jun 2014 16:19:39 GMT

is this what you are after?

data _null_;

old='15.04.2014 10:15';

new=input(old,ANYDTDTM23.);

put new=datetime23.;

run;

Re: Char to Numeric with Date Format

danimian — Wed, 18 Jun 2014 17:03:54 GMT

I need text '15.04.2014 10:15' from old in new as date in format DD.MM.YYY HH:MM

Re: Char to Numeric with Date Format

slchen — Wed, 18 Jun 2014 17:49:57 GMT

PROC FORMAT;
picture dt low-high='%0d.%0m.%0Y %0H:%0M' (datatype=datetime);
RUN;

data _null_;

old='15.04.2014 10:15';

new=input(old,ANYDTDTM23.);

put new=dt.;

run;

Re: Char to Numeric with Date Format

Haikuo — Wed, 18 Jun 2014 17:50:30 GMT

There is no out-of box format for your requirement, except you have to make your own:

proc format;

picture cus_dtm

low - high = '%0d.%0m.%Y %0h:%0M'

(datatype=datetime);

run;

data _null_;

old='15.04.2014 10:15';

new=input(old,ANYDTDTM23.);

put new=cus_dtm20.;

run;

Re: Char to Numeric with Date Format

danimian — Fri, 20 Jun 2014 16:03:59 GMT

Yes Its working fine now. Thanks a lot.

Best Regards

Re: Char to Numeric with Date Format

kristi_jencks — Fri, 04 Aug 2017 04:34:54 GMT

My current character value is stored as DD.MM.YYY HH:MM. when changing it to the numeric value.

data _null_;
old='15.04.2014 10:15';
new=input(old,ANYDTDTM23.);
put new=datetime23.;
run;

Re: Char to Numeric with Date Format

AndrewHowell — Thu, 03 Aug 2017 06:04:34 GMT

One further recommendation:

Store the format somewhere permanently, so it's always available, and you don't have to keep redefining it in each SAS session:

proc format library=corpdata.myfmts;
     picture cus_dtm
           low -  high      =  '%0d.%0m.%Y %0h:%0M'
           (datatype=datetime);
run;

options fmtsearch=(corpdata.myfmts),

data _null_;
     old='15.04.2014 10:15';
     new=input(old,ANYDTDTM23.);
     put new=cus_dtm20.;
run;