topic Re: How to specify different colors on DATALABELATTRS? in SAS Data Management

How to specify different colors on DATALABELATTRS?

edison83 — Thu, 06 Oct 2022 20:40:31 GMT

Hi everyone, maybe it is a dumb question for you guys expert on this.

I have the following code but i would like to have the % values to have the same color for each respective line color.

In other words, the three % values on top of the red line to be also red, the values of the blue dashed line to be blue, and the respective green line values to be also green.

What am I missing?

ods graphics on / ATTRPRIORITY=NONE;
proc sgplot data=m3 noborder ;
scatter x=PRRSV2 y=Mu3 / group=PRRSresult1
yerrorupper=upperMux2 yerrorlower=LowerMux2 group=PRRSresult1 groupdisplay=cluster clusterwidth=0.05 ;
series x=PRRSV2 y=Mu3 / group=PRRSresult1 GROUPLC=PRRSresult1 GROUPLP=PRRSresult1 GROUPMC=PRRSresult1
DATALABEL=Mu4 lineattrs=(thickness=3px) DATALABELATTRS=(Color=black Family="Times" Size=10 Style=normal Weight=bold) name="series" ;
styleattrs datacontrastcolors=(VIYG VIGB VIPK) datalinepatterns=(solid dash 16) DATASYMBOLS=(circleFilled SquareFilled) ;
xaxis VALUEATTRS=(Color=black Family=times Size=12
Style=normal Weight=bold) label='Dx Code - PRRS' labelattrs=(size = 14) type=discrete;
yaxis VALUEATTRS=(Color=black Family=times Size=12
Style=normal Weight=bold)label='W2F mortality (%)' labelattrs=(size = 14);
keylegend "series" / titleattrs=(weight=bold size = 10) location=inside position=topleft across=1 title= "Sow farm PRRS status";
title "(Sow farm PRRS status) * (Dx Code - PRRS)";
run;

Thanks!

Re: How to specify different colors on DATALABELATTRS?

Ksharp — Fri, 07 Oct 2022 10:32:05 GMT

Remove
"DATALABEL=Mu4"
and add one more SCATTER
" scatter x=PRRSV2 y=Mu3 /markerchar=Mu4 discreteoffset=0.5 ; "

Re: How to specify different colors on DATALABELATTRS?

edison83 — Fri, 07 Oct 2022 15:41:31 GMT

Thanks a lot, that worked just fine.

Can you help me with one last question. I am struggling to find a statement now for changing the location of the labels using the "markerchar="

See below how they are being plotted on the chart now.

Re: How to specify different colors on DATALABELATTRS?

Ksharp — Sat, 08 Oct 2022 12:48:31 GMT

/*or using TEXT statement instead of markerchar= */
proc sgplot data=sashelp.class nocycleattrs;
scatter x=age y=height/ group=sex;
text x=age y=height text=name/strip contributeoffsets=none group=sex position=ne ; /*position=nw|se|sw|top|bottom*/
run;

/*or make a new variable to relocate "markerchar="*/
data class;
 set sashelp.class;
 new_height=height+1;
run;
proc sgplot data=class nocycleattrs;
scatter x=age y=height/ group=sex;
scatter x=age y=new_height /markerchar=name group=sex ; 
run;

Re: How to specify different colors on DATALABELATTRS?

edison83 — Mon, 10 Oct 2022 16:35:00 GMT

Thanks, that worked just fine!