topic Replace missing value with latest instance of an observation in SAS Data Management

Replace missing value with latest instance of an observation

SidB — Thu, 14 Apr 2022 18:42:28 GMT

I need to replace all the missing values (in previous instances) with the latest instance values

ID Start End

1 3/4/2022

1 3/5/2022 3/6/2022

needs to looks like -

ID Start End

1 3/4/2022 3/6/2022

1 3/5/2022 3/6/2022

Re: Replace missing value with latest instance of an observation

PGStats — Thu, 14 Apr 2022 18:59:52 GMT

The double DOW technique is well suited for this kind of operation:

data have;
input ID (Start End) (:mmddyy.);
format start end yymmdd10.;
datalines;
1   3/4/2022  .
1   3/5/2022   3/6/2022
;

data want;
do until (last.id);
    set have; by id;
    if not missing(end) then latest = max(latest, end);
    end;
do until (last.id);
    set have; by id;
    end = coalesce(end, latest);
    output;
    end;
drop latest;
run;

Re: Replace missing value with latest instance of an observation

mkeintz — Thu, 14 Apr 2022 23:55:52 GMT

The double DOW, as @PGStats suggests is well suited to your task.

The core logic of the double DOW is to read all obs for each ID twice, the first time to establish the latest END value, and the second time to assign that value when necessary.

The code below also reads each ID twice, but uses the "IN=" dataset name parameters (in the SET statement) to identify the equivalent of each DO loop:

data have;
input ID (Start End) (:mmddyy.);
format start end yymmdd10.;
datalines;
1   3/4/2022  .
1   3/5/2022   3/6/2022
run;

data want (drop=_:);
  set have (in=firstpass)  have (in=secondpass);
  by id;
  retain _last_end;
  if first.id then call missing(_last_end);
  if firstpass then _last_end=coalesce(end,_last_end);
  if secondpass;
  end=coalesce(end,_last_end);
run;

Re: Replace missing value with latest instance of an observation

SidB — Fri, 15 Apr 2022 00:33:13 GMT

@PGStats Thank you so much! this worked