topic Re: Choose the first 5 colums and rename with unknown variable names in SAS Data Management

Choose the first 5 colums and rename with unknown variable names

SASAID — Sat, 21 Jul 2018 23:30:41 GMT

Hello,

Is it possible to choose the first 5 columns of a table and to rename it without knowing the variable names ? Thanks a lot for answering my question.

Re: Choose the first 5 colums and rename with unknown variable names

TomKari — Sun, 22 Jul 2018 00:09:58 GMT

Can't completely answer this one without knowing a little more about what you're trying to do, but here's how to get the column names in order.

Tom

proc sql noprint;
	create table x as select name from dictionary.columns where
		libname = "SASHELP" and memname = "SHOES" and varnum <= 5
	order by varnum;
run;

Re: Choose the first 5 colums and rename with unknown variable names

Reeza — Sun, 22 Jul 2018 01:56:21 GMT

Yes it’s possible by reading the names into macro variables and using those instead.

@SASAID wrote:
Hello,

Is it possible to choose the first 5 columns of a table and to rename it without knowing the variable names ? Thanks a lot for answering my question.

Re: Choose the first 5 colums and rename with unknown variable names

Patrick — Sun, 22 Jul 2018 11:04:35 GMT

@SASAID

Not sure about a use case for this other than "academic" but here you go:

data have;
  set sashelp.class;
run;

%let nvarsToChange=3;
proc sql noprint;
  select 
    cats(name,'=',substrn(cats('renamed_',name),1,32)) into :_rename_list separated by ' '
  from dictionary.columns
  where 
    libname='WORK' 
    and memname='HAVE'
    and varnum<=&nvarsToChange
  ;
quit;
%put %nrbquote(&_rename_list);

proc datasets lib=work nolist nowarn;
  modify have;
    rename &_rename_list;
  run;
  contents data=have order=varnum;
  run;
quit;

Re: Choose the first 5 colums and rename with unknown variable names

SASAID — Sun, 22 Jul 2018 13:03:57 GMT

Perfect! Thank you very much