topic Drop an entire array after using it in SAS Data Management

Drop an entire array after using it

StephanDup — Mon, 30 Oct 2017 08:19:08 GMT

Good day. I have created a lag of all my variables and would like to drop the original variables and only keep the lagged variables.

The following code was used unsuccessfully:

data want;
  set have;
  array vars{*} _numeric_;
  array L1vars{1000};
  do i = 1 to dim(vars);
    L1vars{i} = lag(vars{i});
  end;
  drop i;
  drop vars;
 run;

Re: Drop an entire array after using it

RW9 — Mon, 30 Oct 2017 09:27:57 GMT

You can't drop arrays like that. Arrays are only temporary references for groups of variables, not elements themselves. You can of course pre-build the vars:

proc sql;
  select distinct NAME
  into   :V separated by " "
  from   SASHELP.VCOLUMN
  where  LIBNAME="WORK"
    and  MEMNAME="HAVE"
    and  TYPE="num";
quit;

data want;
  set have;
  array vars{*} &V.;
  array L1vars{1000};
  do i = 1 to dim(vars);
    L1vars{i} = lag(vars{i});
  end;
  drop i &V.;
 run;

Re: Drop an entire array after using it

Ksharp — Mon, 30 Oct 2017 12:43:57 GMT

Since your matrix refer to alll numeric variables. Try

drop _numeric_;

Re: Drop an entire array after using it

Astounding — Mon, 30 Oct 2017 13:11:55 GMT

@Ksharp gets partial credit here. It's the right statement to add, but has to be added in exactly the right place.

In a DATA step, _numeric_ refers to all numeric variables that have been defined so far. To get rid of the original numeric variables, the order of the statements must specifically be:

array vars {*} _numeric_;

drop _numeric_;

array L1vars .........

That's the only point in your DATA step where _numeric_ refers to all the original numeric variables coming from HAVE. (Yes, technically the DROP statement could come between the SET statement and the first ARRAY statement.)