topic Re: Challenge Question in Programming 2: Creating and using custom formats in Programming 1 and 2

Challenge Question in Programming 2: Creating and using custom formats

monsoon1 — Thu, 02 Feb 2023 18:24:28 GMT

Hi everyone, Im a bit stuck on understanding this code. Can someone advise on what is the purpose of proc format cntlout, bold below

proc format cntlin=pg2.np_types_regions;
run;

proc format cntlout = typfmtout;
select $TypCode;
run;

data typfmt_update;
    set typfmtout pg2.np_newcodes;
    keep FmtName Start Label;
    FmtName='$TypCode';
run;

proc format cntlin= typfmt_update;
run;

title1 'Park Frequencies by Type';
proc freq data=pg2.np_summary;
    table Type / nocum;
    format Type $TypCode.;
run;
title;

Thanks

Re: Challenge Question in Programming 2: Creating and using custom formats

Kathryn_SAS — Fri, 03 Feb 2023 14:50:52 GMT

The CNTLOUT= option on the PROC FORMAT statement creates an output data set with all the variables associated with the $Typcode format. You can view this data set by adding the following:

proc print data=typfmtout;

run;

Re: Challenge Question in Programming 2: Creating and using custom formats

Tom — Fri, 03 Feb 2023 15:09:45 GMT

Probably because it is taking the scenic route?

The first two steps can be reduced to one (or none if you just use WHERE= dataset option in third step).

data typfmt_update;
  set pg2.np_types_regions(where=(upcase(fmtname)='TYPCODE'))
      pg2.np_newcodes
  ;
  keep fmtname type start label;
  fmtname='TYPCODE';
  type='C';
run;

Basically you are adding the observations from PG2.NP_NEWCODE to the set of values used to define $TYPCODE format. So that the next step can use PROC FORMAT to actually create the format. Which is used by the final step to change how the values or TYPE are displayed (and hence how they are grouped by PROC FREQ).