topic Re: Query on Lesson 4 - Computing new Columns - Practice level 2 in Programming 1 and 2

Query on Lesson 4 - Computing new Columns - Practice level 2

mk133201 — Thu, 21 Jul 2022 08:13:13 GMT

Hi,

I am reading through the solution for Level 2 Practice in Lesson 4 Creating New Columns with Character and Date Functions.

In the original file, pg1.eu_occ, the type for "YearMon" is character. Hence after substring the Year and Month, should they be character type too?

But does it not need to be in numeric format for the MDY function to work? Can anyone please help on this, thank you so much!

data eu_occ_total;
    set pg1.eu_occ;
    Year=substr(YearMon,1,4);
    Month=substr(YearMon,6,2);
    ReportDate=MDY(Month,1,Year);
    Total=sum(Hotel,ShortStay,Camp);
    format Hotel ShortStay Camp Total comma17.
           ReportDate monyy7.;
    keep Country Hotel ShortStay Camp ReportDate Total;
run;

Re: Query on Lesson 4 - Computing new Columns - Practice level 2

FreelanceReinh — Thu, 21 Jul 2022 09:10:14 GMT

Hi @mk133201 and welcome to the SAS Support Communities!

You are right. The SUBSTR function returns character values and the MDY function expects numeric arguments. Therefore, these three lines of code are inconsistent:

    Year=substr(YearMon,1,4);
    Month=substr(YearMon,6,2);
    ReportDate=MDY(Month,1,Year);

The code will work nevertheless because of automatic type conversion: Character arguments of the MDY function containing suitable digit strings like "2017" for Year would be converted to the corresponding numeric values. But this is bad practice because it would cause a note in the log saying

NOTE: Character values have been converted to numeric values at the places given by: (Line):(Column).
...

which should be avoided. The same type of note would be written to the log if Year and Month were numeric variables in dataset pg1.eu_occ, as the automatic character-to-numeric conversion would then occur in the two assignment statements.

A clean solution would convert the substrings explicitly by means of the INPUT function, e.g.:

Year =input(substr(YearMon,1,4),32.);
Month=input(substr(YearMon,6,2),32.);

(The informat lengths, here: 32, could also be chosen as 4 and 2, resp.)

Re: Query on Lesson 4 - Computing new Columns - Practice level 2

mk133201 — Thu, 21 Jul 2022 13:11:43 GMT

Many thanks for your clear explanation 🙂