Thema "Schleife mit Multiplikation über mehrere Zeilen" in CoDe SAS German

Schleife mit Multiplikation über mehrere Zeilen

hs_do — Mon, 25 Jan 2016 09:21:59 GMT

Hallo zusammen!

Ich möchte ein Produkt bilden über mehrere Zeilen im Datensatz hinweg.

Sobald eine Zeile mit einer neuen id auftritt, soll neu gerechnet werden.

Eine Summe schaffe ich zu berechnen, aber wenn ich das + gegen ein * tausche, erhalte ich eine Fehlermeldung.

Hier ein kurzes Beispielprogramm (die fehlerhafte Produktberechnung ist auskommentiert):

data test;
input id wert;
cards;
1 3
1 5
1 7
2 1
2 2
2 3
2 4
3 5
3 5
3 5
run;

Proc sort data=test;
by id wert;
run;

data test2;
set test;
by id;
if first.id then do;
summe = 0;
summe = summe + wert;
*produkt = 1;
*produkt = produkt * wert;
end;
else do;
summe + wert;
*produkt * wert;
end;
run;

Habt ihr eine Idee für mich, wie ich das hinkriege?
Vielen Dank vorab für Eure Hilfe!

Harald

Re: Schleife mit Multiplikation über mehrere Zeilen

AndreasMenrath — Mon, 25 Jan 2016 09:27:52 GMT

Hallo Harald,

da du für die Multiplikation kein SUM Statement verwenden kannst, musst du die Variable produkt explizit per RETAIN Statement so deklarieren, dass ihr Wert über die Datensatziterationen erhalten bleibt.

Hier ein lauffähiges Beispiel:

data test2;
 set test;
 by id;
 retain produkt 0;
 if first.id then do;
   summe = 0;
   summe = summe + wert;
   produkt = 1; 
 end;
 else do;
   summe + wert;
 end;
 produkt = produkt * wert;
run;

Gruß,

Andreas

Re: Schleife mit Multiplikation über mehrere Zeilen

WolfgangHornung — Mon, 25 Jan 2016 09:28:23 GMT

Hallo Harald,

summe+wert;

ist eine sogenannte SUM-Anweisung, die die Variable summe automatisch retained. Eine Entsprechende MAL-Anweisung gibt es leider nicht. Folgendermaßen funktioniert es:

data test2;
 set test;
 by id;
 retain produkt 1;
 if first.id then do;
  produkt = 1;
 end;
 produkt=produkt * wert;
run;

Wichtig dabei ist es die Variable produkt auf retain zu setzen, das bedeutet, dass der errechnete Wert beibehalten wird, bis er bei einem Gruppenwechsel (first.id) neu initialisiert wird.

Viele GRüße

Wolfgang

Re: Schleife mit Multiplikation über mehrere Zeilen

hs_do — Mon, 25 Jan 2016 10:17:37 GMT

Hallo Andreas,

vielen Dank für Deine schnelle Hilfe!

Gruß,

Harald

Re: Schleife mit Multiplikation über mehrere Zeilen

hs_do — Mon, 25 Jan 2016 10:18:14 GMT

Hallo Wolfgang,

vielen Dank für Deine schnelle Hilfe!

Gruß,

Harald

Re: Schleife mit Multiplikation über mehrere Zeilen

mariusg — Mon, 25 Jan 2016 12:16:22 GMT

und zur Abwechslung mal etwas proc sql 😉

Marius

data test;
	input id wert;
	cards;
1 3
1 5
1 7
2 1
2 2
2 3
2 4
3 5
3 5
3 5
run;

proc sql;
	SELECT
		id,
		round
	(CASE
		WHEN MinVal = 0 THEN 0
		WHEN mod(Neg, 2) = 1 THEN -1 * EXP(ABSMult)
		ELSE EXP(ABSMult)
	END)
as Mult_Wert
	from(
		SELECT
			id, 
			SUM(log(ABS(ifn(wert=0, 0,wert)))) AS ABSMult,
			SUM(SIGN
		(CASE 
			WHEN wert < 0 THEN 1 
			ELSE 0 
		END)
			) AS Neg,
			MIN(ABS(wert)) AS MinVal
		FROM
			test
		GROUP BY
			id
			) test
	;
quit;

Re: Schleife mit Multiplikation über mehrere Zeilen

Dennis_V — Tue, 26 Jan 2016 12:06:48 GMT

Mit PROC SQL

DATA TEST;
  INPUT ID WERT;
  CARDS;
1 3
1 5
1 7
2 1
2 2
2 3
2 4
3 5
3 5
3 5
RUN;

PROC SQL;
  SELECT ID, 
         EXP(SUM(LOG(WERT))) AS PRODUKT
  FROM TEST
  GROUP BY ID;
QUIT;

Re: Schleife mit Multiplikation über mehrere Zeilen

mariusg — Tue, 26 Jan 2016 12:15:49 GMT

Hi Dennis_V,

mal mit einem Wert von 0 getestet? 😉

Viele Grüße
Marius

Re: Schleife mit Multiplikation über mehrere Zeilen

FreelanceReinh — Tue, 26 Jan 2016 14:07:35 GMT

Auch wenn man nur positive Eingangswerte zulässt, sollte m. E. ein ROUND um das Formelergebnis nicht fehlen. Es könnte ja sein, dass mit der Variable PRODUKT weitergearbeitet wird (z. B. if produkt<125 then ...). Dann stellen die möglichen Rundungsfehler ein Risiko dar. Schon im vorliegenden Zahlenbeispiel weichen 2 der 3 Ergebnisse vom erwarteten ganzzahligen Produkt ab (jedenfalls auf meinem Rechner).

Werden prinzipiell auch nicht ganzzahlige Eingangswerte zugelassen, ist bei der Wahl der Rundungseinheit auf die Größenordnung der erwarteten Ergebnisse zu achten. In vielen Fällen ähnlich dem vorliegenden Beispiel dürfte sich 10^-8 als Rundungseinheit eignen, also

ROUND(EXP(SUM(LOG(WERT))), 1E-8) AS PRODUKT