topic Re: a suggestion and a question on Macro1 m104p05 about local and global macro concepts in Advanced Programming

a suggestion and a question on Macro1 m104p05 about local and global macro concepts

dxiao2017 — Mon, 25 May 2026 17:24:48 GMT

Hi may I suggest that for Macro1 lesson practice m104p05, the example of local macro, the name of the macro, scope, is very confusing (and it is good to use other name for the macro), I spent about 1 hour on it and finally figured out what was the issue that confused me. The code is as follows:

%macro scope;
%let stormtype1=Some damage;
%let stormtype2=Extensive damage;
%let stormtype3=Devastating damage;
%let stormtype4=Catastrophic damage;
%let stormtype5=Widespread catastrophic damage;
%put _user_;
%mend scope;
%scope;

After run the code, the log is as follows:

69         %macro scope;
 70         %let stormtype1=Some damage;
 71         %let stormtype2=Extensive damage;
 72         %let stormtype3=Devastating damage;
 73         %let stormtype4=Catastrophic damage;
 74         %let stormtype5=Widespread catastrophic damage;
 75         %put _user_;
 76         %mend scope;
 77         %scope;
 SCOPE STORMTYPE1 Some damage
 SCOPE STORMTYPE2 Extensive damage
 SCOPE STORMTYPE3 Devastating damage
 SCOPE STORMTYPE4 Catastrophic damage
 SCOPE STORMTYPE5 Widespread catastrophic damage
 
 GLOBAL GRAPHINIT GOPTIONS RESET=ALL GSFNAME=_GSFNAME;
 GLOBAL GRAPHTERM GOPTIONS NOACCESSIBLE;

Seeing the log I had an wrong impression that global macro is explicitly displayed in the log as GLOBAL ones and local macro is explicitly displayed in the log as SCOPE ones, and I even tried at least 6 to 10 times to use %put _scope_; and %put _local_; to display my local macros in the log but failed, until I somehow luckily tried the follows:

%macro test;
%global stormtype1;
%let stormtype1=Some damage;
%let stormtype2=Extensive damage;
%let stormtype3=Devastating damage;
%let stormtype4=Catastrophic damage;
%let stormtype5=Widespread catastrophic damage;
%put _user_;
%mend test;
%test;

And get this log as follows, and then I had the correct concepts, that is:

(a) unlike global macros displayed in the log as GLOBAL ones, local macro is NOT explicitly displayed in the log as something like LOCAL ones or SCOPE ones, it is the macro name TEST,

(b) if I want to display local macros in the log, I have to use %put _user_; inside the macro, if I use %put _user_; or %put _all_; outside this macro, then only global and automatic macros are displayed, local macros are not displayed, and

(c) so there is a question, is there any statement (aside from, for example, like %put &stormtype1;) I can use here, outside the %macro test macro, to display all of the local macro only (and do not display the global and automatic ones)?

69         %macro test;
 70         %global stormtype1;
 71         %let stormtype1=Some damage;
 72         %let stormtype2=Extensive damage;
 73         %let stormtype3=Devastating damage;
 74         %let stormtype4=Catastrophic damage;
 75         %let stormtype5=Widespread catastrophic damage;
 76         %put _user_;
 77         %mend test;
 78         %test;
 TEST STORMTYPE2 Extensive damage
 TEST STORMTYPE3 Devastating damage
 TEST STORMTYPE4 Catastrophic damage
 TEST STORMTYPE5 Widespread catastrophic damage

 GLOBAL GRAPHINIT GOPTIONS RESET=ALL GSFNAME=_GSFNAME;
 GLOBAL GRAPHTERM GOPTIONS NOACCESSIBLE;

 GLOBAL STORMTYPE1 Some damage

Another thought is: use %global statement very carefully because it is very easily to get macros confused created in the session.

Re: a suggestion and a question on Macro1 m104p05 about local and global macro concepts

Tom — Mon, 25 May 2026 18:39:45 GMT

I think you are looking for the _LOCAL_ keyword in the %PUT statement. That will exclude the GLOBAL (including the "automatic"ly global) macro variables.

I agree that the name of the macro is confusing.

SCOPE is already a little overloaded with meanings:

It has a general meaning in computer programming:

Scope defines where variables can be accessed or modified in your program. It determines the visibility and lifetime of variables - in other words, which parts of your program can "see" and use a particular variable. https://www.w3schools.com/programming/prog_scope.php

It is also used as the name of the variable in SASHELP.VMACRO dictionary view that let's you examine the values of macro variable as a dataset.

It would be better if they used something like MYMACRO as the macro's name instead.

Re: a suggestion and a question on Macro1 m104p05 about local and global macro concepts

Tom — Mon, 25 May 2026 18:49:45 GMT

With _LOCAL_ you only see the macro variables that exist in the innermost symbol table.

With _USER_ you see the macro variables that live in all of the symbol tables (except those that SAS has deemed to be "automatic").

Consider this example of nested macro calls.

%macro outer ;
%local mvar;
%let mvar=outer;
%put %str( );
%put &=sysmacroname _local_;
%put _local_;
%put &=sysmacroname _user_;
%put _user_;
%inner;
%mend outer;
%macro inner;
%local mvar;
%let mvar=inner;
%put %str( );
%put &=sysmacroname _local_;
%put _local_;
%put &=sysmacroname _user_;
%put _user_;
%mend inner;
%outer;

Results

 
 SYSMACRONAME=OUTER _local_
 OUTER MVAR outer
 SYSMACRONAME=OUTER _user_
 OUTER MVAR outer
 GLOBAL CLIENTMACHINE  ...
 ...
  
 SYSMACRONAME=INNER _local_
 INNER MVAR inner
 SYSMACRONAME=INNER _user_
 INNER MVAR inner
 OUTER MVAR outer
 GLOBAL CLIENTMACHINE  ...
 ...

You can see that the call to %PUT _USER_ inside of the macro %INNER shows the local macro variables for both the %INNER and %OUTER macros.

Re: a suggestion and a question on Macro1 m104p05 about local and global macro concepts

Quentin — Tue, 26 May 2026 13:09:41 GMT

@dxiao2017 wrote in part:

(b) if I want to display local macros in the log, I have to use %put _user_; inside the macro, if I use %put _user_; or %put _all_; outside this macro, then only global and automatic macros are displayed, local macros are not displayed, and

(c) so there is a question, is there any statement (aside from, for example, like %put &stormtype1;) I can use here, outside the %macro test macro, to display all of the local macro only (and do not display the global and automatic ones)?

A key point about (b) and (c) is that local macro variables only exist while a macro is executing. So if you have a local macro variable &x defined in your macro %test, that macro variable does not exist outside of %test. Thus there is no statement that can be run outside of the macro %test that will display its macro variables. As Tom has shown, inside the macro %test both %put _user_ ; and %put _local_ ; are useful for displaying macro variables.

Re: a suggestion and a question on Macro1 m104p05 about local and global macro concepts

Tom — Tue, 26 May 2026 13:49:21 GMT

If you want to see the values of all current LOCAL macro variables you could query DICTIONARY.MACROS (or SASHELP.VMACRO).

 73         proc sql;
 74         describe view sashelp.vmacro;
 NOTE: SQL view SASHELP.VMACRO is defined as:
 
         select *
           from DICTIONARY.MACROS;
 
 75         describe table dictionary.macros;
 NOTE: SQL table DICTIONARY.MACROS was created like:
 
 create table DICTIONARY.MACROS
   (
    scope char(32) label='Macro Scope',
    name char(32) label='Macro Variable Name',
    offset num label='Offset into Macro Variable',
    value char(200) label='Macro Variable Value'
   );
 
 76         quit;

For an example of using that check out this %symget() macro which lets you retrieve the value of a macro variable that you could not normally access because it is "hidden" by the existence of another macro variable with the same name in a more local scope.

Re: a suggestion and a question on Macro1 m104p05 about local and global macro concepts

dxiao2017 — Wed, 27 May 2026 11:07:04 GMT

Thanks a lot Tom, for the clarification of the word SCOPE, I now understand the concept: tells me where I can see, access, and modify a macro. I will practice a little bit on sashelp.vmacro dictionary later on. And you are right, I was trying to use %put _local_ while posting the question but nothing was displayed in the log then I thought I did not remember the statement correctly.

Re: a suggestion and a question on Macro1 m104p05 about local and global macro concepts

dxiao2017 — Wed, 27 May 2026 11:26:02 GMT

Thanks a lot @Tom for the further explanations. So %put _local_ displays the local macros, %put _user_ displays both global and local ones (that are user-defined), and %put _all_ displays global and automatic ones (yet does not display local ones because local ones only exist in the innermost symbol table).

I think your example is good, yet it is a little bit complicated, I tried an easier example practiced a bit, as follows:

%macro test1;
%global a;
%let a=avalue;
%let b=bvalue;
%put _global_;
%put _local_;
%mend test1;
%test1;

 69         %macro test1;
 70         %global a;
 71         %let a=avalue;
 72         %let b=bvalue;
 73         %put _global_;
 74         %put _local_;
 75         %mend test1;
 76         %test1;
 GLOBAL A avalue

 TEST1 B bvalue

Re: a suggestion and a question on Macro1 m104p05 about local and global macro concepts

dxiao2017 — Wed, 27 May 2026 11:42:33 GMT

Hi @Quentin I think it is a brilliant point you answered my question that the local macros only exist when it is executing. That is why I use %put _local_ and %put _user_ outside the macro %test and got nothing in the log message (and that's the part previously I did not understand). While reply @Tom 's answer I practiced use _local_ inside the macro to display the local ones, now I tried put _local_ outside the macro (and the local one does not shows in the log), as follows:

%macro test2;
%global c;
%let c=cvalue;
%let d=dvalue;
%mend test2;
%test2;
%put _global_;
%put _local_;

 69         %macro test2;
 70         %global c;
 71         %let c=cvalue;
 72         %let d=dvalue;
 73         %mend test2;
 74         %test2;
 75         %put _global_;
 
 GLOBAL C cvalue

 76         %put _local_;
 77

Re: a suggestion and a question on Macro1 m104p05 about local and global macro concepts

dxiao2017 — Wed, 27 May 2026 13:24:17 GMT

Hi @Tom thanks a lot for your further answer which remind me that I can use dictionary.macros to see the macro variables. I checked out the link of %symget() macro, I think it is good yet a bit too advanced for me at the moment so I would not further explore it, hope I have chances to use these macros in future.

I practiced a bit (of creating macro variables in different ways and use %put _global_; _local_; and dictionary.macros to display the macros) as follows:

(1) create and display global macros (no local macro was created or displayed according to my log and result)

data test3;
   input id1 $ id2 $;
   datalines;
e evalue
f fvalue
;
run;
data test4;
   input name $ value $;
   datalines;
g gvalue
h hvalue
;
run;
%let i=ivalue;
data _null_;
   set test3;
   call symputx(id1,id2);
run;
proc sql noprint;
select name,value
   into :name1-,:value1-
   from test4;
quit;
%put _global_;
%put _local_;
proc sql;
select * 
   from dictionary.macros
   where name in ('E','F','G','H','I',
                  'NAME1','NAME2',
                  'VALUE1','VALUE2');
quit;

93         %put _global_;

 GLOBAL E evalue
 GLOBAL F fvalue

 GLOBAL I ivalue
 GLOBAL NAME1 g
 GLOBAL NAME2 h

 GLOBAL VALUE1 gvalue
 GLOBAL VALUE2 hvalue

94         %put _local_;

(2) create and display local macros (no global macro was created or displayed according to my log and result)

data test5;
   input id1 $ id2 $;
   datalines;
j jvalue
k kvalue
;
run;
data test6;
   input name $ value $;
   datalines;
l lvalue
m mvalue
;
run;
%macro testmcr;
%let n=nvalue;
data _null_;
   set test5;
   call symputx(id1,id2);
run;
proc sql;
select name,value
   into :mname1-,:mvalue1-
   from test6;
quit;
%put _global_;
%put _local_;
proc sql;
select * from dictionary.macros;
quit;
%mend testmcr;
%testmcr;

 99         %mend testmcr;
 100        %testmcr;
 
 NOTE: There were 2 observations read from the data set WORK.TEST5.

 TESTMCR J jvalue
 TESTMCR K kvalue
 TESTMCR MNAME1 l
 TESTMCR MNAME2 m
 TESTMCR MVALUE1 lvalue
 TESTMCR MVALUE2 mvalue
 TESTMCR N nvalue

I have not try these (the above) out on positional or keyword macro parameters, or on more complicate ones, for example, the nested macros with both global and local macro variables and parameters, too complicated. Will try them later on.

Re: a suggestion and a question on Macro1 m104p05 about local and global macro concepts

Tom — Wed, 27 May 2026 15:15:45 GMT

There are a few other wrinkles you have not explored with your examples.

When you create parameters for a macro they are LOCAL macro variables to that macro.

When you reference a macro variable SAS will look for that macro starting with the innermost scope and working its way out to the GLOBAL "scope" (note that GLOBAL and AUTOMATIC macro variables are in the same symbol table and so in the same scope even though SAS prints them with different "scope" values when using %PUT keywords or looking at DICTIONARY.MACROS).

This is even true when you CREATE the macro variable. So if you write this line inside a macro:

%let i=ivalue;

And the macro variable I already exists in some outer scope (such as GLOBAL) then the value of that macro variable is modified. To avoid this use the %LOCAL statement to create a new macro variable in the local scope before assigning it a value. Or in a DATA step you can skip the %LOCAL statement by using the 'L' modifier when using the CALL SYMPUTX() method to assign the value to a macro variable. That will force the macro variable into the local symbol table.

An even stranger wrinkle is that SAS will not create the local symbol table for a macro until is it runs a statement that the SAS macro compiler thinks should cause it to need a local symbol table. This means that any new macros that are created (by using some method that the macro compiler does not notice) will be made in the scope of the calling environment, even if that calling environment is another macro execution and not open code. Try this example:

%macro outer;
	%let myvar=OUTER ;
	%put &=sysmacroname BEFORE;
	%put _local_;
	%inner;
	%put &=sysmacroname AFTER;
	%put _local_;
%mend outer;
%macro inner;
	%put &=sysmacroname BEFORE;
	%put _local_;
	data _null_;
	  call symput('myvar2','inner');
	run;
	%put &=sysmacroname AFTER;
	%put _local_;
%mend inner;
%outer;

Where is the macro variable MYVAR2 created?

 SYSMACRONAME=OUTER BEFORE
 OUTER MYVAR OUTER
 SYSMACRONAME=INNER BEFORE
 
 NOTE: DATA statement used (Total process time):
       real time           0.00 seconds
       cpu time            0.00 seconds
       
 
 SYSMACRONAME=INNER AFTER
 SYSMACRONAME=OUTER AFTER
 OUTER MYVAR OUTER
 OUTER MYVAR2 inner

Now see what happens if you add a %LET statement to the inner macro. Try first adding it AFTER the DATA step. Where is MYVAR2 created?

Then try adding it BEFORE the DATA step. Where is MYVAR2 created?