topic incomprehensible message of data: Developing Macro Applications in Advanced Programming

incomprehensible message of data: Developing Macro Applications

CorinneT — Fri, 17 Sep 2021 14:58:18 GMT

Hi,

Please, could you help me regarding my program which doesn't work well. Thanks in advance.

I have this message on my Log which is contradictory:

ERROR: BE is an invalid country code

Valid country codes include

AT,AU,BE,CA,CH,CI,DE,DK,EG,ES,FI,FR,GB,GR,HR,IE,IL,IN,IT,LT,LU,MZ,NL,NO,NZ,PL,PT,SE,SI,TR,US,YU,ZA

103

104

105 OPTIONS NONOTES NOSTIMER NOSOURCE NOSYNTAXCHECK;

115

My progrm code is below:

%macro customerlist(ctry)/minoperator;
%if %SUPERQ(ctry)= %then %do;
title "Customers from all countries";
proc sgplot data=mc1.customers noborder;
vbar Group / filltype=gradient stat=percent;
yaxis grid display=(noticks noline nolabel);
run;
%end;
%else %do;
%let ctry=%upcase(&ctry);
proc sql ;
select distinct Country
into :ctrylist separated by ','
from mc1.customers;
quit;

%if %SUPERQ(ctry) in %SUPERQ(ctrylist) %then %do;
title "Customers from &ctry";
proc sgplot data=mc1.customers noborder;
vbar Group / filltype=gradient stat=percent;
yaxis grid display=(noticks noline nolabel);
where Country="&ctry";
run;
%end;
%else %do;
%put ERROR: &ctry is an invalid country code;
%put ERROR- Valid country codes include &ctrylist;
%end;

%end;
%mend customerlist;

%customerlist(be)

Re: incomprehensible message of data: Developing Macro Applications

PaigeMiller — Fri, 17 Sep 2021 21:10:35 GMT

Please provide us the entire LOG for this macro (and in the future, always provide the entire LOG for the code in question, always, always, always). First turn on these options before you run the code.

options mprint mlogic symbolgen;

Then copy the log (all of it, every single line in the log from this macro, do no chop anything out of the log) and paste it into the window that appears when you click on the </> icon — DO NOT SKIP THE INSTRUCTIONS IN RED.

Re: incomprehensible message of data: Developing Macro Applications

ballardw — Fri, 17 Sep 2021 22:05:10 GMT

Syle note: Generally Error checks, like in the list go at the beginning of a macro, not after generating a bunch of procedure steps that could fail.

I see option minnoperator. How about Mindelimiter? Did you set that to comma?

Note: may want a different delimiter than comma as comma is used is many places in macro code and can easily lead to other hard to trace issues like "too many parameter" errors.

Re: incomprehensible message of data: Developing Macro Applications

Quentin — Fri, 17 Sep 2021 22:07:29 GMT

Your list of countries in CTRYLIST is delimited by commas.

If you want to use the IN operator in the macro language, it's probably a good practice to specify the delimiter in the macro definition, i.e.:

%macro customerlist(ctry)/minoperator mindelimiter=',' ;

If you don't specify the delimiter on the macro definition, you'll be at the mercy of whatever value is set for mindelimiter when the macro is called. The default is a space, which would explain why your macro isn't working as you had hoped.

Re: incomprehensible message of data: Developing Macro Applications

Tom — Fri, 17 Sep 2021 23:29:00 GMT

You added the MINOPERATOR option to make sure the macro supports the IN operator, but you did not tell it what character to use a the delimiter.

But you don't really need to use the IN operator in your macro code.

Since you already had to run some SAS code just test the country code with the SAS code. SAS code is much easier to debug than macro code.

%macro customerlist(ctry);
%local ctrylist found ;
%if 0=%length(ctry) %then %let ctry=ALL;
%else ctry=%qupcase(&ctry);

%if &ctry = ALL %then %let found=1;
%else %do ;
  proc sql noprint;
    select distinct country
         , max(upcase(country)="&ctry")
      into :ctrylist separated by ' '
         , :found 
    ;
  quit;
%end;

%if not &found %then do;
   %put ERROR: &ctry is an invalid country code;
   %put ERROR- Valid country codes include &ctrylist;
%end;
%else %do;

TITLE "Customers from country: &ctry";

  proc sgplot data=mc1.customers noborder;
    vbar Group / filltype=gradient stat=percent;
    yaxis grid display=(noticks noline nolabel);
  %if &ctry ne ALL %then %do;
    where Country="&ctry";
  %end;
  run;
%end;
%mend customerlist;

%customerlist(be)

Re: incomprehensible message of data: Developing Macro Applications

CorinneT — Sat, 18 Sep 2021 09:40:32 GMT

Thank you so much, Quentin. It's the solution 🙂
with:
" mindelimiter=','"

Re: incomprehensible message of data: Developing Macro Applications

CorinneT — Sat, 18 Sep 2021 09:46:24 GMT

Yes, it's a good tip regarding the "options mprinen ....."
I have to add it to monitor my macro program.
Thanks