All Graphics Programming posts

Re: Axis table overlapping the first value

Jay54 — Thu, 22 Jul 2021 00:49:41 GMT

is right. It is hard to help without the code and data. That said, if you must use GTL, try putting a bottom INNERMARGIN in the LAYOUT OVERLAY.

However, if all you need is the table below the graph, it is easier to use SGPLOT procedure. SGPLOT will take care of a lot of details for you.

Re: Axis table overlapping the first value

ballardw — Thu, 22 Jul 2021 00:34:09 GMT

Because many things in graphics can interact we need the entire template definition. Best would be some data and the Proc SGrender using the template to create the images.

Some possible ideas to look into that are relatively easy:

Make the graph area bigger

Make the font for the label smaller

Axis table overlapping the first value

new510 — Wed, 21 Jul 2021 23:26:37 GMT

Hi All,

I am trying to add axis table, and the label(stratum) overlaps the first value. I am using the following code for the axis table.

layout overlay / walldisplay=none xaxisopts=(display=none OFFSETMIN=0);
axistable x=TATRISK value=ATRISK /title="Number At Risk" display=(label) valueattrs=(size=8pt) class=stratum colorgroup=stratum VALUEHALIGN=right;
endlayout;

Example fig:

The label was supposed to be Treat11, and the first value is truncated to 41 instead of 2841.

I really appreciate any help you can provide.

Re: a percentage-based bar graph

DanH_sas — Sun, 18 Jul 2021 22:06:58 GMT

For the record, the default percentage basis is the entire graph output, including all BY-groups. To change this basis, use the PCTLEVEL option like you did set the level you want to be the basis for 100%. In SGPLOT, there are three levels: Graph (the default), BY (for BY-groups), and Group (all groups within a category = 100%). For SGPANEL, there are four levels: Graph, BY, Cell (all bars in each cell = 100%), and Group.

Re: a percentage-based bar graph

dustychair — Sun, 18 Jul 2021 06:07:10 GMT

Thank you for your response. I think I got it. I modified my code as below and it worked.

proc sgplot data=alt_listening PCTLEVEL=BY;
title "Proficiency Level: List 1-2";
vbar listening_pl / stat=pct transparency=0.25 fillattrs=(color=black) ;
yaxis label= 'Percent' ;
xaxis label= 'Proficiency Level';
by cluster_listening;
run;

Thank you again

Re: a percentage-based bar graph

djrisks — Sun, 18 Jul 2021 06:07:13 GMT

Hello,
Please can you also include your data or an example of your data?

a percentage-based bar graph

dustychair — Sun, 18 Jul 2021 05:52:44 GMT

Hi all,

I have a categorical variable in my data. I am trying to draw a bar graph for this variable based on the percents. The below code is working but the sum of percentages is not 100%. I don't know how it is calculating this. Is there an easy way to draw a percentage-based bar graph?

Thank you,

proc sgplot data=alt_listening;
title "Proficiency Level: List 1-2";
vbar listening_pl / stat=pct transparency=0.25 fillattrs=(color=black) ;
yaxis label= 'Percent' ;
xaxis label= 'Proficiency Level';
by cluster_listening;
run;

Re: Fun With SAS ODS Graphics: Happy Ba(r)stille Day!

RobertAllison_SAS — Wed, 14 Jul 2021 18:20:00 GMT

- an elegant solution ... but it takes the 'bar' out of Ba(r)stille day! 🙂

Re: Fun With SAS ODS Graphics: Happy Ba(r)stille Day!

Ksharp — Wed, 14 Jul 2021 13:09:36 GMT

BLOCK also can do this simple .


data flag; do c=1 to 3; output; end; run;                                    * Generate flag data - tricolour of blue/white/red;

ods graphics / reset height=4in width=6in antialias noborder;                     * 2:3 proportion (height:width);

proc sgplot data=flag noautolegend; * Plot #1: Generate bar chart;
styleattrs datacolors=(cx0055A4 cxFFFFFF cxEF4135);
block x=c block=c/novalues nooutline  ;
xaxis type=discrete integer display=none   offsetmax=0.17 offsetmin=0.17;
yaxis display=none;
run;

Fun With SAS ODS Graphics: Happy Ba(r)stille Day!

tc — Wed, 14 Jul 2021 03:30:42 GMT

Flag of France - Take 3!

A quick SAS ODS Graphics take on the Flag of France for Bastille Day - third time's the charm!

* Fun With SAS ODS Graphics: Happy Ba(r)stille Day! (vertical bar chart Flag of France)
  Based on colors/dimensions at en.wikipedia.org/wiki/Flag_of_France;

data flag; do c=1 to 3; output; end;                                     * Generate flag data - tricolour of blue/white/red;

ods graphics / reset height=4in width=6in antialias;                     * 2:3 proportion (height:width);

proc sgplot data=flag;                                                   * Plot #1: Generate bar chart;
vbar c;

proc sgplot data=flag;                                                   * Plot #2: Generate bar chart with colors of Flag of France;
vbar c / colorresponse=c colormodel=(cx0055A4 cxFFFFFF cxEF4135);

proc sgplot data=flag aspect=.66667 noautolegend pad=0 noborder nowall;  * Plot #3: Generate bar chart as tricolour Flag of France;
vbar c / barwidth=1 colorresponse=c colormodel=(cx0055A4 cxFFFFFF cxEF4135) nooutline baselineattrs=(thickness=0);
xaxis display=none min=.5 max=3.5 offsetmin=0 offsetmax=0 type=linear;   * Suppress axis/padding;
yaxis display=none min=0 max=1 offsetmin=0 offsetmax=0;
run;

Flag of France - Take 1!Flag of France - Take 2!

Re: combine Barchart with Circles

Reeza — Mon, 12 Jul 2021 20:06:38 GMT

wrote:

i am sorry, since i marked it . i am unable to make any changes

Actually it can ben updated, click the three dots beside the post currently marked as solved.

As to which solution to mark as correct - the OP should mark the solution that best fits their needs, ie if the SGPLOT solution is simpler that is a valid selection over an SGRENDER solution.

Re: combine Barchart with Circles

pmksasbi — Mon, 12 Jul 2021 17:46:45 GMT

i am sorry, since i marked it . i am unable to make any changes

Re: How to make tickstyle=inside work for BOTH major and minor tick marks?

JonathanNitzan — Sun, 11 Jul 2021 22:34:53 GMT

Thank you for the answers -- much appreciated. I had hoped that SAS 9.4 1M7 fixed this shortcoming. It's bizarre that this feature is not available.

Re: proc lifetest not all tatrisk values are not being displayed.

S_RAVI — Sat, 10 Jul 2021 00:10:57 GMT

Yes, I do have 4 value on x-axis

Re: Create and IMAGE file of output from PROC REPORT

JeffMeyers — Fri, 09 Jul 2021 22:04:20 GMT

I believe if you put your proc report into the ods printer destination you can save the output to a png. Use options papersize as well to help control the size.

Re: Create and IMAGE file of output from PROC REPORT

djrisks — Fri, 09 Jul 2021 21:29:03 GMT

Hi, looking at old SAS community posts, I do not believe that is possible. However, I believe that you could use the XAXISTABLE and YAXISTABLE statements in SGPLOT to produce the report that you want. If you have an example, I could help. You said that you will annotate in SGPLOT too, so it could be better to start from there aswell.

Otherwise, you could take a snippet or screenshot of the report and then save that, and then use that image with SGPLOT.

Create and IMAGE file of output from PROC REPORT

data_null__ — Fri, 09 Jul 2021 20:54:16 GMT

Can I create output from PROC REPORT as an image (PNG). I want to annotate a figure (SGPLOT) with a small table of statistics, using IMAGE function seems like an easy way, but I also don't want to create the image file by hand. I don't think INSET or AXISTABLE are suitable that's why I think IMAGE would be nice.

Re: How to make tickstyle=inside work for BOTH major and minor tick marks?

djrisks — Fri, 09 Jul 2021 17:12:42 GMT

Hi ,

Robert Allison shows an example at the link below. You basically need to create the tick marks yourself. The TICKSTYLE = Inside, as you said only works for major tick values.

https://communities.sas.com/t5/Graphics-Programming/Creating-an-axis-in-GTL-with-both-major-and-minor-tick-marks/td-p/690688

Re: How to make tickstyle=inside work for BOTH major and minor tick marks?

ballardw — Fri, 09 Jul 2021 17:12:06 GMT

I suggest posting your template and Sgrender code used plus some data.

Templates can be a bit picky and we need to see everything involved to understand what may be happening.

How to make tickstyle=inside work for BOTH major and minor tick marks?

JonathanNitzan — Fri, 09 Jul 2021 17:00:26 GMT

1. I'm using proc template, trying to have my tick marks plotted inside rather than outside. I'm using option tickstyle=inside, but this option seems to affect only the major tick marks, not the minor ones.

2. I'm using SAS 9.4 1M7.

3. Any suggested solution for how to have BOTH major and minor tick marks inside?

Thank you.

Re: Cannot get imagemap to work on SAS Studio in server environment

DanH_sas — Fri, 09 Jul 2021 16:07:56 GMT

Setting:

ods graphics / imagemap=on;

should work regardless of your SAS environment.

Re: Cannot get imagemap to work on SAS Studio in server environment

kate-1mr — Fri, 09 Jul 2021 15:22:24 GMT

Hi! I have same problem. Could you send me how you solved this problem.
Many Thanks:)

Re: How to reduce spacing in Shewhart chart?

PaigeMiller — Thu, 08 Jul 2021 23:38:28 GMT

Let me alert you to change a small part of the above code, removing HAXIS=1 TO 6, as most likely you will have more than 6 months in your real data.

Re: How to reduce spacing in Shewhart chart?

annaabimbola — Thu, 08 Jul 2021 23:03:46 GMT

It worked!!!!

Thank you so much for the help and patience.

Re: How to reduce spacing in Shewhart chart?

PaigeMiller — Thu, 08 Jul 2021 22:49:51 GMT

Since I am not going to type in your screen captures of data, I made up my own data to illustrate.

data have;
    input measureperiodid :date9. neonatald;
    format measureperiodid date9.;
    cards;
01OCT2020 40
01NOV2020 3
01DEC2020 19
01FEB2021 40
;

proc sql;
    create table minmax as 
    select min(measureperiodid) as mindate,max(measureperiodid) as maxdate
    from have;
run;

/* Create index values */
data index;
	set minmax;
	index=0;
	date=mindate;
	do until (date>=maxdate);
	    date=intnx('month',mindate,index,'b');
	    index=index+1;
	    year=year(date);
	    month=month(date);
	    output;
    end;
    format date date9.;
    keep index date year month;
run;

data final;
    merge have index(rename=(date=measureperiodid));
    by measureperiodid;
    if missing(neonatald) then neonatald=0;
run;

proc shewhart data=final;
	irchart neonatald*index(year month)/blockpos=3 haxis=1 to 6;
	label year='Year' month='Month';
run;

Re: How to reduce spacing in Shewhart chart?

annaabimbola — Thu, 08 Jul 2021 23:04:33 GMT

This is an initiative implemented in hospitals. Each hospital reports the number of days a patient stays in the hospital every month. The goal is to create these control charts every month to see how effective the initiative is, so the neonatald variable changes every month.

Re: How to reduce spacing in Shewhart chart?

PaigeMiller — Thu, 08 Jul 2021 22:13:03 GMT

Show me a portion of your data. Explain what changes from month to month that it would need automation.

Re: How to reduce spacing in Shewhart chart?

annaabimbola — Thu, 08 Jul 2021 21:43:44 GMT

What code can I use to do that?

Re: How to reduce spacing in Shewhart chart?

PaigeMiller — Thu, 08 Jul 2021 21:17:08 GMT

Assigning index numbers can be automated.

Re: How to reduce spacing in Shewhart chart?

annaabimbola — Thu, 08 Jul 2021 20:59:36 GMT

Thanks PaigeMiller, this worked.

I'm writing the codes for an external organization and they need something that will be more automated. They have to create these control charts every month because this is an ongoing project and I won't be the one doing that, so I was wondering if there was a way to do this without having to assign index integers to each month every time they do this.

I really appreciate the help.

Re: How to reduce spacing in Shewhart chart?

ballardw — Thu, 08 Jul 2021 18:15:49 GMT

Don't know if this will fix the specific issue by I think you may have "nicer" axis appearance if you use

xschart neonatald*measureperiodid/haxis= '01SEP2020'd to '01MAR2021'd by month;

Re: How to reduce spacing in Shewhart chart?

PaigeMiller — Thu, 08 Jul 2021 18:14:38 GMT

As I suggested in your other thread, make the horizontal axis to be the numbers 1, 2, ... and then use a block variable to identify the months.

Also note that using by 31 in your code, you will not really be displaying months, but time periods of 31 days.

How to reduce spacing in Shewhart chart?

annaabimbola — Thu, 08 Jul 2021 23:05:25 GMT

Hi All,

I'm want to create an XSchart.

The chart was split into 4 instead of 1. Please how do I make this come out as just 1 chart?

The data points for the subgroup variable are 09/01/2020, 10/01/2020,...01/01/2021

Please see the code.

title "Length of Stay";
symbol v=dot;

proc shewhart data=work.nowsbaseline_sorted;
	xschart neonatald*measureperiodid/haxis= '01SEP2020'd to '01MAR2021'd by 31;
run;

Any help is greatly appreciated.

Thanks in advance!

Re: combine Barchart with Circles

djrisks — Wed, 07 Jul 2021 17:56:50 GMT

You're welcome. I also believe that my answer should have been marked as the solution since I created the data and answered it first.

Re: combine Barchart with Circles

pmksasbi — Wed, 07 Jul 2021 17:50:25 GMT

thank you all

Re: combine Barchart with Circles

Ksharp — Wed, 07 Jul 2021 12:25:18 GMT

data testdata;
  length city $9;
  city = "London"; dollar = 50; scatter = 45; output;
  city = "Dubai"; dollar = 40; scatter = 35; output;
  city = "New York"; dollar = 20; scatter = 25; output;
  city = "Las Vegas"; dollar = 60; scatter = 30; output;
run;

proc sgplot data=testdata noautolegend;
vbar city/response=dollar;
vline city/response=scatter LINEATTRS=(thickness=0) MARKERATTRS=(size=20 symbol=circlefilled color=orange) markers;
run;

Re: combine Barchart with Circles

Reeza — Tue, 06 Jul 2021 23:55:11 GMT

proc sgplot data=testdata;
vbarparm category = city response=dollar;  *bar graph;
scatter x= city y=clients / y2axis; *scatter plot;
run;

See the section in the docs titled Basic-Compatible Bar Chart Examples for various other examples here

https://documentation.sas.com/doc/en/vdmmlcdc/1.0/grstatproc/n121lznfa1jnlvn1q95t0r5sd2gq.htm#p11mehfndp2u8tn1ulq0zvi2hmrb

wrote:

Sample

x-axis with description of city , y axis with dollar, right side with no of assigned clients

Re: proc lifetest not all tatrisk values are not being displayed.

djrisks — Tue, 06 Jul 2021 22:38:21 GMT

Hello, have you used the TICKVALUELIST option to specify the x-axis values? Do you see 4 on the x-axis?

Re: combine Barchart with Circles

djrisks — Tue, 06 Jul 2021 22:32:59 GMT

Hello,

Here is some example code that you can use:

data testdata;
  length city $9;
  city = "London"; dollar = 50; scatter = 45; output;
  city = "Dubai"; dollar = 40; scatter = 35; output;
  city = "New York"; dollar = 20; scatter = 25; output;
  city = "Las Vegas"; dollar = 60; scatter = 30; output;
run;

proc template;
  define statgraph barwithcircle;
    begingraph;
	  layout overlay;
	    barchart x = city y = dollar;
		scatterplot x = city y = scatter / markerattrs = (size = 20 color = orange symbol = circlefilled);
	  endlayout;
	endgraph;
  end;
run;

proc sgrender data = testdata template = barwithcircle;
run;

The code produces the graph below.

Re: How to change font in a plot

djrisks — Tue, 06 Jul 2021 22:00:43 GMT

You're welcome. You can add the GraphBackground class to change the fill color from grey to white, as seen below.


proc template;
  define style styles.new_font;
  parent = styles.default;

  class GraphBackground /
      color = white;

  class GraphFonts
      "Fonts used in graph styles" /
      'GraphValueFont' = ("Arial",9pt)
      'GraphLabelFont' = ("Times New Roman Uni",10pt,
      bold);
  end;
run;


ods listing style = styles.new_font gpath = "C:\graph";
proc sgplot data=sashelp.class;
  scatter x=height y=weight / group=sex;
run;

Re: combine Barchart with Circles

pmksasbi — Tue, 06 Jul 2021 21:39:35 GMT

Sample

x-axis with description of city , y axis with dollar, right side with no of assigned clients

Re: combine Barchart with Circles

Reeza — Tue, 06 Jul 2021 21:29:24 GMT

What would that even look like? What would be on the axis? Is it dual axis?

combine Barchart with Circles

pmksasbi — Tue, 06 Jul 2021 21:22:40 GMT

HI ,

can anyone please give some example code for the vertical bar graph with circles plotting on it.

Thanks,

Mahesh

Re: How to change font in a plot

marta25 — Tue, 06 Jul 2021 13:02:02 GMT

Thanks, this is nice, however now the background fill of the plot is grey. How do I change this to white/transparent?

Re: How to change font in a plot

RobertAllison_SAS — Tue, 06 Jul 2021 11:47:38 GMT

Another option would be to use the older SAS/Graph proc gplot, where you can control the text font with "goptions ftext=".

Re: Fun With SAS ODS Graphics: Patriotic Pom Pom July 4th Wreath (Bubble+Scatter Plots)

Ksharp — Mon, 05 Jul 2021 09:20:01 GMT

Forgive me to steal your code to plot Chinese flag .

proc format;                              * Assign red/white/blue colors based on angles of wedges; 
value rwb -250--140='Blue' -270--260, 80-90, 20-40, -40--20, -100--80 ='Red'  
          50-70, -10-10, -70--50, -130--110='White'; 

data wreath;                              * Generate points for July 4th 'wreath';
retain size 1 txt '10.1*国庆节*快乐';
do a=90 to -270 by -10;                   * Generates points for balloons;
  do r=.5 to 1 by .15;                    * Three points for each angle;  
    x=r*cos(a*constant('pi')/180);
    y=r*sin(a*constant('pi')/180);        
    c=put(a,rwb.);                        * Assign color;
    output;
  end;
end;
x=.; y=.;                                 * Generate points for stars;



start=unicode('\u2605');
  r=0.5; a=-210    ;             
  xs=r*cos(a*constant('pi')/180);
  ys=r*sin(a*constant('pi')/180);    
  rotate=30; 
  output;
  r=0.55; a=-230     ;            
  xs=r*cos(a*constant('pi')/180);
  ys=r*sin(a*constant('pi')/180);  
  rotate=0;  
  output;
  r=0.7; a=-240     ;            
  xs=r*cos(a*constant('pi')/180);
  ys=r*sin(a*constant('pi')/180); 
  rotate=-30;  
  output;
  r=0.9; a=-240     ;            
  xs=r*cos(a*constant('pi')/180);
  ys=r*sin(a*constant('pi')/180);   
  rotate=-60;  
  output;

xs=.; ys=.;                               
  r=0.9; a=-215    ;             
  xs1=r*cos(a*constant('pi')/180);
  ys1=r*sin(a*constant('pi')/180);   
  rotate=0;   
  output;

xs1=.; ys1=.;                               * Generate point for text;
xs=.; ys=.;                               * Generate point for text;
xt=0; yt=0;
output;
                                          * Patriotic Pom Pom Wreath (Bubble+Scatter Plots);
proc sgplot data=wreath aspect=1 noautolegend noborder;
bubble x=x y=y size=size / fillattrs=(color=red)               /* Red, white and blue bubbles */
       dataskin=pressed  nooutline bradiusmin=.23in bradiusmax=.25in;   
text x=xs y=ys text=start/  strip textattrs=(size=20pt color=yellow weight=bold) contributeoffsets=none rotate=rotate ;    
text x=xs1 y=ys1 text=start/  strip textattrs=(size=50pt color=yellow weight=bold) contributeoffsets=none rotate=rotate ;                                              
 
xaxis display=none; yaxis display=none;   * Look Ma, no axes!;
text x=xt y=yt text=txt / strip textattrs=(size=18pt color=red weight=bold) 
     splitchar='*' splitpolicy=splitalways contributeoffsets=none; * Happy 4th of July!; 
run;

Re: Fun With SAS ODS Graphics: Patriotic Pom Pom July 4th Wreath (Bubble+Scatter Plots)

Jay54 — Sun, 04 Jul 2021 04:25:27 GMT

Nice work, TC. Great to see this visually appealing graphic using skins with bubbles. No annotation needed.

Fun With SAS ODS Graphics: Patriotic Pom Pom July 4th Wreath (Bubble+Scatter Plots)

tc — Sun, 04 Jul 2021 03:52:02 GMT

Patriotic Pom Pom Wreath

A SAS ODS Graphics bubble plot take on a neat Etsy Patriotic Pom Pom Wreath. Have a Happy 4th, all!

* Fun With SAS ODS Graphics: Patriotic Pom Pom July 4th Wreath (Bubble+Scatter Plots)
  Inspired by Patriotic Pom Pom wreath at etsy.com/listing/964348987/patriotic-pom-pom-wreath-red-white-and;

proc format;                              * Assign red/white/blue colors based on angles of wedges; 
value rwb -250--140='Blue' -270--260, 80-90, 20-40, -40--20, -100--80 ='Red'  
          50-70, -10-10, -70--50, -130--110='White'; 

data wreath;                              * Generate points for July 4th 'wreath';
retain size 1 txt 'HAPPY*4TH OF JULY!';
do a=90 to -270 by -10;                   * Generates points for balloons;
  do r=.7 to 1 by .15;                    * Three points for each angle;  
    x=r*cos(a*constant('pi')/180);
    y=r*sin(a*constant('pi')/180);        
    c=put(a,rwb.);                        * Assign color;
    output;
  end;
end;
x=.; y=.;                                 * Generate points for stars;
do a=-150 to -240 by -15;                 * In the blue wedge of wreath;                
  if r=.9 then r=.8; else r=.9;           * Alternate location of stars (radius=.8 or .9);          
  xs=r*cos(a*constant('pi')/180);
  ys=r*sin(a*constant('pi')/180);         
  output;
end;
xs=.; ys=.;                               * Generate point for text;
xt=0; yt=0;
output;
                                          * Patriotic Pom Pom Wreath (Bubble+Scatter Plots);
proc sgplot data=wreath aspect=1 noautolegend noborder;
styleattrs datacolors=(red white navy);
symbolchar name=uniStar char='2605'x;     * Unicode 5-pointed star;
bubble x=x y=y size=size /                /* Red, white and blue bubbles */
       dataskin=pressed group=c nooutline bradiusmin=.23in bradiusmax=.25in;   
scatter x=xs y=ys /                       /* White stars */                          
        markerattrs=(symbol=unistar size=36pt color=white);        
xaxis display=none; yaxis display=none;   * Look Ma, no axes!;
text x=xt y=yt text=txt / strip textattrs=(size=18pt color=navy weight=bold) 
     splitchar='*' splitpolicy=splitalways contributeoffsets=none; * Happy 4th of July!; 
run;

Re: How to change font in a plot

djrisks — Fri, 02 Jul 2021 00:20:32 GMT

Also, this link can show you how to find which fonts are available:

https://documentation.sas.com/doc/en/pgmsascdc/9.4_3.5/graphref/n0840ghr9b9y3bn0zphem54hvgbt.htm

Re: How to change font in a plot

djrisks — Fri, 02 Jul 2021 00:09:45 GMT

Hello,

Below is an example of how to use different fonts. GraphLabelFont controls the axis labels and the legend label. GraphValueFont controls the axis tick values, and the values within the legend. Also, make sure that you actually look at the graph file that is being outputted, i.e. the .PNG file on your C drive.


proc template;
  define style styles.new_font;
  parent = styles.default;
  class GraphFonts
      "Fonts used in graph styles" /
      'GraphValueFont' = ("Arial",9pt)
      'GraphLabelFont' = ("Times New Roman Uni",10pt,
      bold);
  end;
run;


ods listing style = styles.new_font gpath = "C:\graph";
proc sgplot data=sashelp.class;
  scatter x=height y=weight / group=sex;
run;

Re: xaxis marks correlated with x-values

Jason2020 — Thu, 01 Jul 2021 14:32:43 GMT

That was a simple solution. Thank you very much.

Re: xaxis marks correlated with x-values

JeffMeyers — Thu, 01 Jul 2021 14:20:40 GMT

You x axis is discrete instead of linear. Add TYPE=linear to your x axis statement.

xaxis marks correlated with x-values

Jason2020 — Thu, 01 Jul 2021 14:06:08 GMT

Greetings,

I am using proc sgplot to model the relationship between bone level and follow up years in two treatment groups (A/B). The issue I have is that the tick marks of the x-axis are not spaced right. In other words, the 1 year and 6 years are spaced equally. I hope someone can show me how to space the marks so that they are correlated with the number of years. I included below a sample of my data, the program I used, and the resulting figure.

Thank you.

subject group followup level

02 A 1.0 4.7

02 A 4.5 4.6

02 A 6.0 4.9

02 A 0.0 1.6

03 A 2.0 2.3

03 A 6.0 1.4

03 A 0.0 1.5

07 B 1.0 1.1

07 B 2.0 1.4

07 B 4.5 1.3

07 B 6.0 1.3

07 B 0.0 1.1

08 A 2.0 1.0

08 A 4.5 1.0

proc sgplot data=p1;

vline followup / response=level group=group

stat=mean limitstat=stderr lineattrs=(thickness=6px);

yaxis label="Bone Level (mm)"

valueattrs=(size=18pt) labelattrs=(size=20pt weight=bold);

xaxis discreteorder=unformatted label="Follow up (years)"

valueattrs=(size=18pt) labelattrs=(size=20pt weight=bold);

keylegend /location=inside valueattrs=(size=18pt)

title="" titleattrs=(size=16pt);

run;

How to change font in a plot

marta25 — Thu, 01 Jul 2021 07:04:38 GMT

Hello,

It seems a very easy question but somehow I am struggling with this.

I just want to change the FONT (not font size, this I can do easily) of all text in a plot (in SGPLOT): axis labels and values, legend items...

I guess I have to define a new style, something like:

proc template;
define style my_style;
parent=styles.htmlblue;
class GraphValueText / font = ("<sans-serif>, <MTsans-serif>",20pt);
end;

How can I set the font to Times New Roman, or Arial, etc, instead of sans-serif?

Where can I find a list of available fonts?

And how do I apply the new style to the plot?

Could someone give an example (as easy as possible)?

Re: using annotate in proc sgplot

ChrisNZ — Wed, 30 Jun 2021 06:32:13 GMT

Can you pass to the SG team the request to add notes in the log when the annotate data is not suitable, like SAS/Graph does?

Re: using annonate in sgplot

Anita_n — Wed, 30 Jun 2021 06:19:12 GMT

okay, thanks for the explanation

Re: using annotate in proc sgplot

Anita_n — Wed, 30 Jun 2021 06:16:40 GMT

: Great job Robert, that is exactly what I wanted. You have really helped me 😊

Re: using annonate in sgplot

ChrisNZ — Tue, 29 Jun 2021 22:05:55 GMT

>Is the max value allowed for Y=1?

Y displayed as 100% means Y=1 right?

So your chart displays Y values between 0 and 1. Now your annotate data specifies text to display at Y=300. How do you want this to happen?

It seems out-of-plot annotate positions don't generate notes for SG like they do for SAS/Graph?

[Edit:

Looking at 's code, I see that the SG annotate variables are different from the SAS/Graph ones.

Seemingly like the OP, I am an old SAS/Graph hand and didn't catch that.

Again, notes should be printed in the log when the annotate data is not usable though. They really should.]

Re: using annotate in proc sgplot

RobertAllison_SAS — Tue, 29 Jun 2021 19:01:53 GMT

Since nobody jumped on this one, I'll go ahead and finish it...

Here's how to create an annotate dataset suitable for use with sgplot. Hopefully I've understood the values you're wanting on the bar segments, and the value you wanted annotated at the top of each bar (... if not, it should be easy for you to modify).

proc sql noprint;
create table myanno as
select unique year, sum(number_of_cases) as year_sum
from mydat
group by year;
quit; run;

data myanno; set myanno;
length label $100 anchor x1space y1space textweight $50;
layer="front";
function="text"; textcolor="gray44"; textsize=10; textweight='bold';
width=100; widthunit='percent'; 
label=trim(left(put(year_sum,comma8.0))); 
x1space='datavalue'; 
y1space='datapercent'; 
x1=year;
y1=100;
anchor='bottom'; 
run;

title "My Custom Bar Chart, with annotated sum at top of bar";
proc sgplot data=mydat dattrmap=myattrmap sganno=myanno pad=(bottom=5%) noborder;
vbarparm category=year  response=rel_freq /group=level groupdisplay=stack attrid=level 
 seglabel seglabelattrs=(size=8pt color=gray55) seglabelformat=percentn7.2
 seglabelfitpolicy=none barwidth=0.6 missing;
xaxis grid type=discrete discreteorder=data;
xaxis display=(nolabel) valueattrs=(family="verdana" size=8pt) fitpolicy=rotate ValuesRotate=Vertical;
yaxis display=(nolabel) valueattrs=(family="verdana" size=8pt) offsetmax=.10;
keylegend / location=outside position=bottomright across=0 title="" valueattrs=(size=8pt family="verdana") outerpad=(top=0.2cm) noborder;
run;

Re: using annotate in proc sgplot

RobertAllison_SAS — Tue, 29 Jun 2021 17:02:41 GMT

Looks like you're trying to use the old SAS/Graph (gplot) style annotate dataset, with the new Base SAS (sgplot) graphics - that won't work. 🙂

Here's a slightly cleaned-up version of your code, which might be a good starting place for you (or someone to help) add the sgplot-style annotate. (Does this graph look like you're wanting, so far?)

data mydat;
infile datalines;
input year	level $12.	number_of_cases;
datalines;
2001	1	        90	
2001	2	        1	 
2001	3	        5	 
2001	4	        22	
2001	no cases	35	
2002	1	        99	
2002	2	        4	 
2002	3	        2	 
2002	4	        55	
2002	no cases	39	
2003	1	        200
2003	2	        45	
2003	3	        77	
2003	4	        39	
2003	no cases	23	
2004	1	        205
2004	2	        19	
2004	3	        29	
2004	4	        15	
2004	no cases	18	
2005	1	        159
2005	2	        323
2005	3	        99	
2005	4	        10	
2005	no cases	28	
2006	1	        88	
2006	2	        10	
2006	3	        16	
2006	4	        55	
2006	no cases	8	 
;
run;

proc sql noprint;
create table mydat as
select mydat.*, 
sum(number_of_cases) as number_of_cases_sum
from mydat
group by year
order by year, level;
quit; run;

data mydat; set mydat;
format rel_freq percent7.0;
rel_freq=number_of_cases/number_of_cases_sum;
run;

data myattrmap;
	infile datalines;
	input id $6. value $10. fillcolor $8.;
	datalines;
level no cases  CXA9A9A9 
level 1         CX00FFFF 
level 2         CXFF7F50 
level 3         CXFFF8DC 
level 4         CX006400 
;
run;

proc sgplot data=mydat dattrmap=myattrmap pad=(bottom=5%) noborder;
vbarparm category=year  response=rel_freq /group=level groupdisplay=stack attrid=level 
 seglabel seglabelattrs=(size=8pt color=gray55) seglabelformat=percentn7.2
 seglabelfitpolicy=none barwidth=0.6 missing;
xaxis grid type=discrete discreteorder=data;
xaxis display=(nolabel) valueattrs=(family="verdana" size=8pt) fitpolicy=rotate ValuesRotate=Vertical;
yaxis display=(nolabel) valueattrs=(family="verdana" size=8pt);
keylegend / location=outside position=bottomright across=0 title="" valueattrs=(size=8pt family="verdana") outerpad=(top=0.2cm) noborder;
run;

Re: proc lifetest not at tatrisk values are not being displayed.

Reeza — Tue, 29 Jun 2021 16:13:11 GMT

I've moved your post to the graphics forum. It would help if you included sample data so we could run the code you've posted or if you cannot use your data use a known data set such as sashelp.heart.

Re: proc lifetest not at tatrisk values are not being displayed.

lrackley — Tue, 29 Jun 2021 15:56:47 GMT

I feel like you should move this to the Graphics Programming forum.

proc lifetest not all tatrisk values are not being displayed.

S_RAVI — Thu, 01 Jul 2021 21:10:34 GMT

I have used proc lifetest and output the survival plot for atrisk and tatrisk to plot the km plot. My survival output dataset has tatrisk values as 0, 2, 4, 6. But when I output it using proc template and sgrender only 0, 2, 6 values are being displayed.

Re: using annonate in sgplot

Anita_n — Tue, 29 Jun 2021 12:19:02 GMT

Is the max value allowed for Y=1?

Re: using annonate in sgplot

ChrisNZ — Tue, 29 Jun 2021 10:28:55 GMT

1. Copy and paste the code you provided: It doesn't run.

2. You plot percentages (max value Y=1 ) and use YSYS=2 (data coordinates) but your annotate data has Y in the hundreds

using annotate in proc sgplot

Anita_n — Tue, 29 Jun 2021 13:01:35 GMT

Dear all,

I have the following code to draw a bar chart and label each bar with the sum total of each bar or each year using an annotate dataset. The seglabels should be in percentage as shown in the graph, since I can't use datalabel here, I creatde an annotate dataset but can't get it working, I might probably be missing something somewhere. any help? My code is as below

data mydat;
infile datalines;
input year	level $12.	number_of_cases;
datalines;
2001	1	        90	
2001	2	        1	 
2001	3	        5	 
2001	4	        22	
2001	no cases	35	
2002	1	        99	
2002	2	        4	 
2002	3	        2	 
2002	4	        55	
2002	no cases	39	
2003	1	        200
2003	2	        45	
2003	3	        77	
2003	4	        39	
2003	no cases	23	
2004	1	        205
2004	2	        19	
2004	3	        29	
2004	4	        15	
2004	no cases	18	
2005	1	        159
2005	2	        323
2005	3	        99	
2005	4	        10	
2005	no cases	28	
2006	1	        88	
2006	2	        10	
2006	3	        16	
2006	4	        55	
2006	no cases	8	 
;
run;
*calculate sum of cases per year;
proc means data=mydat noprint nway;
	class year;
	var number_of_cases;
	output out=sum_mydat (drop=_TYPE_ _FREQ_) sum= / autoname;
run;
*calculate rel. perecntages;
data merge_mydat;
	merge mydat sum_mydat;
	by year;
	format rel_freq percent8.0; 
	rel_freq = divide(number_of_cases,number_of_cases_sum);
    drop number_of_cases_sum;
run;

*create annodat;
data anno;
length function color $8 style $12;                                                                                                  
retain function 'label' when 'a' size 1.25 position '2'                                                                              
          color 'black' xsys '2' ysys '2' style 'Albany AMT' weight 'bold';    
set sum_mydat;

midpoint=year;                                                                                                                       
   y=number_of_cases_Sum;                                                                                                                            
   text=put(number_of_cases_Sum,3.);  

run;

*create attrmap;
data myattrmap;
	infile datalines;
	input id $6. value $10. fillcolor $8. linecolor $9.;
	datalines;
level no cases  CXA9A9A9 CXA9A9A9
level 1         CX00FFFF CX00FFFF
level 2         CXFF7F50 CXFF7F50
level 3         CXFFF8DC CXFFF8DC
level 4         CX006400 CX006400
;
run;

*create chart with labels, the totals of each bar should be written on top of the bar;

proc sgplot data =merge_mydat dattrmap=myattrmap sganno=anno pad=(bottom=5%) noautolegend noborder;
xaxis grid type=discrete discreteorder=data;
vbarparm category= year  response=rel_freq /group=level groupdisplay=stack attrid=level seglabel seglabelattrs=(size=0.25 color="CXFDF5E6") 
seglabelfitpolicy=none barwidth=0.6 missing;
xaxis  display= (nolabel) valueattrs=(family="verdana" size=8pt) fitpolicy=rotate ValuesRotate=Vertical;
yaxis  display= (nolabel) valueattrs=(family="verdana" size=8pt);
keylegend / location=outside position=bottomright across=0 title=" " valueattrs=(size=2 family="verdana") outerpad=(top=0.2cm) noborder;
run;

Re: Proc SGPANEL color by subject

FreelanceReinhard — Mon, 28 Jun 2021 11:50:22 GMT

Hi ,

Compared to the other thread, you inserted the attrid=myid option into the SERIES and SCATTER statements. However, without using the DATTRMAP= option in the SGPANEL statement there's nothing that "myid" refers to. So, in addition to this option you need an attribute map dataset, as described in Example: Create a Panel That Uses an Attribute Map:

data attrmap;
retain ID "myid";
input value markercolor $ linecolor $;
datalines;
1 green green
2 blue  blue
;

proc sgpanel data=have dattrmap=attrmap;
...

Note that most likely you will need to adapt the values of variable value above to your data, unless your variable trt01p_ happens to be numeric with values 1 and 2 (for the groups currently displayed in blue and red, respectively) and not formatted. If trt01p_ is character with values, say, "Active" and "Placebo" or formatted with these format labels, define value as a character variable (of sufficient length) in the DATA step above and replace 1 and 2 by Active and Placebo, resp., in the data lines.

Re: Proc SGPANEL color by subject

RobertAllison_SAS — Mon, 28 Jun 2021 11:06:28 GMT

Looks like duplicate of this solved one(?)

https://communities.sas.com/t5/Graphics-Programming/Proc-SGPANEL-color-by-subject/m-p/749650#M21676

Re: Proc SGPANEL color by subject

ChrisNZ — Mon, 28 Jun 2021 09:05:15 GMT

Moved to Graphics community

Re: DATTRMAP for data label text color

snoopy369 — Thu, 24 Jun 2021 15:21:01 GMT

Ah - that's interesting to hear, and makes sense. That explains why the terminology is "generic" and not specific to the proc - I had wondered why it wasn't just the exact word ("datalabelattrs" or similar), and that explains it. Still would be nice to have the option but if it's not consistent then I understand! Thanks for the explanation.

Re: DATTRMAP for data label text color

DanH_sas — Thu, 24 Jun 2021 15:10:50 GMT

For the record, attribute maps do support a TEXTCOLOR column, but it is used for AXISTABLEs -- not data labels. One possible issue with supporting TEXTCOLOR for data labels is that the map could be set up with text color for one purpose (such as axis tables) but then accidentally get applied to inside data labels of a bar or pie in another part of the report, causing them to be difficult to see. You would have to create a duplicate map, minus the TEXTCOLOR, to work around that issue. One of the main ideas behind attribute maps is that you can define them once to create a standard look for your data and use them for all of your graphs in the report.

Re: DATTRMAP for data label text color

snoopy369 — Thu, 24 Jun 2021 14:11:41 GMT

Thanks for the detailed explanation! I guess that makes sense, but it would be real nice to have more of this stuff exposed to the attribute maps - is it not exposed for a technical reasons, or not a priority compared to other work?

Re: DATTRMAP for data label text color

RobertAllison_SAS — Thu, 24 Jun 2021 11:55:38 GMT

Here's a little more information ...

Using this attribute map:

data attrmap;
id = 'mycolors';
value='M'; fillcolor='lightblue'; textcolor='blue'; output;
value='F'; fillcolor='pink'; textcolor='red'; output;
run;

Let's first step back and take a look at a sgplot bar chart. The attribute map controls the bar segment colors, but if I just use the automatic 'datalabel' option on the vbarparm statement, the textcolor from the attrmap does not have an effect.

title "sgplot vbarparm with datalabel";
proc sgplot data=sashelp.class noautolegend dattrmap=attrmap;
vbarparm category=name response=height/group=sex attrid=mycolors
datalabel=height groupdisplay=cluster;
run;

However, if I add a custom text statement in which I can specify an attrid and group to specifically associate with the text, then the attribute map can control the color of the text.

title "sgplot vbarparm with 'text' statement";
proc sgplot data=sashelp.class noautolegend dattrmap=attrmap;
vbarparm category=name response=height/datalabel group=sex attrid=mycolors;
text x=name y=height text=height / position=top group=sex attrid=mycolors;
run;

Since sgpie does not have a text statement, and only has the automatic labels, it is consistent (with bar charts) that the pie slice color is controlled by the attrmap, but the text would not be controlled by the attrmap:

title "sgpie";
proc sgpie data=sashelp.class noautolegend dattrmap=attrmap;
pie sex / attrid=mycolors;
run;

Re: ODS LAYOUT ABSOLUTE with a BY statement in PROC SGPLOT

PaigeMiller — Thu, 24 Jun 2021 10:50:03 GMT

Once I wrote the output of the PROC DOCUMENT to a data set so I could look at it, it all became very clear to me. Either a macro or CALL EXECUTE based on the data set output from PROC DOCUMENT would get the job done.

Re: DATTRMAP for data label text color

snoopy369 — Wed, 23 Jun 2021 23:17:17 GMT

Sadly, markercolor doesn't work; I think you're probably right and it just isn't supported yet. (I'm also in M6, about to finally get m7 so perhaps it's upgraded in that, but won't have a chance to test for a while.) Thanks!

Re: DATTRMAP for data label text color

ballardw — Wed, 23 Jun 2021 22:57:25 GMT

The documentation at https://documentation.sas.com/doc/en/pgmsascdc/9.4_3.4/grstatproc/n04wp1wciaqxtdn10763lgnuj5dh.htm shows SGPIE is still preproduction so likely has not added in all the features you would like. The Styleattrs statement only shows BACKCOLOR ,background outside the pie, and DATACOLORS as options. So likely what you want for other text has not been implemented.

Just for giggles I might try the MARKERCOLOR option if you haven't tried that yet. It sounds like the only one you may not have tried.

DATTRMAP for data label text color

snoopy369 — Wed, 23 Jun 2021 22:13:20 GMT

Is it possible in SGPIE to use a dynamic data label text color? If so, what is the right variable name?

For example:

data attrmap;
  set sashelp.class;
  if sex='M' then textcolor='blue';
  else textcolor='pink';
  fillcolor='orange';
  id = 'mycolors';
  value = name;
  keep id value textcolor fillcolor;
run;
  
  
proc sgpie data=sashelp.class dattrmap=attrmap;
pie name/attrid=mycolors;
run;

I know that the attribute map is "working" for the rows since the fillcolor is changing, but the textcolor won't change, and I have tried everything I can - textcolor, datalabeltextcolor, datalabelattrs with 'color=blue' - but can't seem to find the option (or, it's not possible?). Don't really want to go the SGANNO route as suggested on a somewhat similar post, so perhaps it's just not possible... Thanks!

Re: ODS LAYOUT ABSOLUTE with a BY statement in PROC SGPLOT

WarrenKuhfeld — Wed, 23 Jun 2021 20:51:32 GMT

I should add that the path is hierarchical with # numbers that identify the sequence so that every object in the document has a unique path.

Re: ODS LAYOUT ABSOLUTE with a BY statement in PROC SGPLOT

WarrenKuhfeld — Wed, 23 Jun 2021 20:37:58 GMT

The heuristic I always use is list the contents of the document, and then use *precisely* the names that the document says are there. I never try to understand or predict them, although before I retired, I could see the logic.

Re: ODS LAYOUT ABSOLUTE with a BY statement in PROC SGPLOT

Rick_SAS — Wed, 23 Jun 2021 20:03:04 GMT

\ProcName\ByGroup\ODSName

This is a version of the familiar PATH that you see when you use ODS TRACE. See SAS Help Center: Paths and Selection

Use

ODS TRACE ON;

prior to writing to the document to see "human readable" versions.

Re: ODS LAYOUT ABSOLUTE with a BY statement in PROC SGPLOT

PaigeMiller — Wed, 23 Jun 2021 19:54:57 GMT

Can you explain this line? Why does SGPlot#1 appear twice? In particular, what does the second SGPlot#1 indicate? Where can I find this in the docs?

replay \SGPlot#1\ByGroup3#1\SGPlot#1;

Re: ODS LAYOUT ABSOLUTE with a BY statement in PROC SGPLOT

WarrenKuhfeld — Wed, 23 Jun 2021 19:25:55 GMT

Thanks for the mention, Rick! It is good to see the ODS document plugged. It is an incredibly useful tool. If you have ever used SAS documentation from any of the products from the advanced analytics group (e.g. STAT, QC, IML, OR, ETS, Enterprise Miner, and so on) you have seen the results of using the ODS document behinds the scenes. SAS is run, output is captured, then output, often subsets of the full output, are replayed into portions of the documentation. Many years ago, output was captured manually and there was no guarantee it was current. For many years now, thanks in part to tools that rely on the ODS document, you can be sure that the output is correct and current.

Re: ODS LAYOUT ABSOLUTE with a BY statement in PROC SGPLOT

PaigeMiller — Wed, 23 Jun 2021 19:20:41 GMT

Thanks, , I will give it a try and report back ... but it does seem like a macro would be useful here too, especially if I have a lot more groups of the BY variable.

Re: ODS LAYOUT ABSOLUTE with a BY statement in PROC SGPLOT

Rick_SAS — Wed, 23 Jun 2021 18:30:30 GMT

A macro is not bad, but (as requested) here is an alternative that uses a SAS feature: replaying output in a different order by using PROC DOCUMENT. Do the following:

1. Read the article "Reorder the output from a BY-group analysis in SAS", which shows how to use ODS DOCUMENT to save your output to a document.

2. Use the second part of your program to write the graphs. (You can omit the ODS LAYOUT statements)

3. Use ODS LAYOUT and PROC DOCUMENT to replay the graphs in the order you want.

I haven't used ODS LAYOUT ABSOLUTE before and I am not skilled with PDF output, but the following (which uses ODS LAYOUT GRIDDED to HTML) should get you started and demonstrate the technique:

proc sort data=sashelp.cars out=cars;
    by origin;
run;
/* write all output to a document */
ods document name=doc(write);      /* wrap ODS DOCUMENT around the output */
proc sgplot data=cars;
    by origin;
    histogram msrp;
run;
proc sgplot data=cars;
    by origin;
    histogram invoice;
run;
proc sgplot data=cars;
    by origin;
    histogram mpg_city;
run;
proc sgplot data=cars;
    by origin;
    histogram horsepower;
run;
ods document close;                /* wrap ODS DOCUMENT around the output */

/* list the outputs */
proc document name=doc(read);
   list / levels=all bygroups;  /* add column for each BY group var */
run;


/* Replay the graphs in a different order */
ods layout gridded rows=2 columns=2 advance=table
    row_gutter=10px column_gutter=10px
    x=.5in y=0.1in width=4in height=2.75in;
proc document name=doc(read);
      replay \SGPlot#1\ByGroup1#1\SGPlot#1;   /* Asia : MSRP */
      replay \SGPlot#2\ByGroup1#1\SGPlot#1;   /* Asia : Invoice */
      replay \SGPlot#3\ByGroup1#1\SGPlot#1;   /* Asia : MPG_City */
      replay \SGPlot#4\ByGroup1#1\SGPlot#1;   /* Asia : Horesepower */
run;quit;
ods layout end;

ods layout gridded rows=2 columns=2 advance=table
    row_gutter=10px column_gutter=10px
    x=.5in y=0.1in width=4in height=2.75in;
proc document name=doc(read);
      replay \SGPlot#1\ByGroup2#1\SGPlot#1;   /* Europe : MSRP */
      replay \SGPlot#2\ByGroup2#1\SGPlot#1;   /* Europe : Invoice */
      replay \SGPlot#3\ByGroup2#1\SGPlot#1;   /* Europe : MPG_City */
      replay \SGPlot#4\ByGroup2#1\SGPlot#1;   /* Europe : Horesepower */
run; quit;
ods layout end;

ods layout gridded rows=2 columns=2 advance=table
    row_gutter=10px column_gutter=10px
    x=.5in y=0.1in width=4in height=2.75in;
proc document name=doc(read);
   replay \SGPlot#1\ByGroup3#1\SGPlot#1;   /* USA : MSRP */
   replay \SGPlot#2\ByGroup3#1\SGPlot#1;   /* USA : Invoice */
   replay \SGPlot#3\ByGroup3#1\SGPlot#1;   /* USA : MPG_City */
   replay \SGPlot#4\ByGroup3#1\SGPlot#1;   /* USA : Horesepower */
run; quit;
ods layout end;

If you don't want to type out all those statements, you can use a DATA _NULL_ step and CALL EXECUTE to automate this process, as shown in "Display output conditionally with PROC DOCUMENT."

A hat tip to who taught me this technique.

ODS LAYOUT ABSOLUTE with a BY statement in PROC SGPLOT

PaigeMiller — Wed, 23 Jun 2021 12:27:02 GMT

I can create an output with four plots on one page using ODS LAYOUT ABSOLUTE, as shown in code #1. But then I want to use a BY statement in PROC SGPLOT, such that the first I get four plots on one page, where all four plots are for the same level of the BY variable and the plots are always in the same position, see code #2.

Code #1, this works as expected, but I have not used a BY statement:

ods pdf file="absolute.pdf";
ods layout absolute ;
ods region x=.5in y=0.1in width=4in height=2.75in;
proc sgplot data=sashelp.cars;
    histogram msrp;
run;
ods region  x=5.1in y=.1in width=4in height=2.75in;
proc sgplot data=sashelp.cars;
    histogram invoice;
run;
ods region  x=.5in y=5.25in width=4in height=2.75in;
proc sgplot data=sashelp.cars;
    histogram mpg_city;
run;
ods region  x=5.1in y=5.25in width=4in height=2.75in;
proc sgplot data=sashelp.cars;
    histogram horsepower;
run;
ods layout end;
ods pdf close;

Now, code #2, with a BY Statement, it doesn't work at all, how can I get something like this to work? I want three output pages, the first page would be four plots for origin='Asia', with MSRP top left, INVOICE top right, MPG_CITY bottom left and HORSEPOWER bottom right; second page would be for origin='Europe', exact same arrangement of plots; third page would be for origin='USA', exact same arrangement of plots.

proc sort data=sashelp.cars out=cars;
    by origin;
run;
ods pdf file="absolute2.pdf";
ods layout absolute ;
ods region x=.5in y=0.1in width=4in height=2.75in;
proc sgplot data=cars;
    by origin;
    histogram msrp;
run;
ods region  x=5.1in y=.1in width=4in height=2.75in;
proc sgplot data=cars;
    by origin;
    histogram invoice;
run;
ods region  x=.5in y=5.25in width=4in height=2.75in;
proc sgplot data=cars;
    by origin;
    histogram mpg_city;
run;
ods region  x=5.1in y=5.25in width=4in height=2.75in;
proc sgplot data=cars;
    by origin;
    histogram horsepower;
run;
ods layout end;
ods pdf close;

Adding: I'm sure I could just wrap this in a macro and loop through all possible values of the BY variable and do it that way, but over the years I have found that SAS is very good at anticipating needs and creating features to do this, so really I'd like to do this without a macro if possible.

Re: Proc SGPANEL color by subject

csa — Tue, 22 Jun 2021 18:29:58 GMT

Thanks

Re: Proc SGPANEL color by subject

ballardw — Tue, 22 Jun 2021 17:53:39 GMT

The colors and order by default come from the current style you have.

You can override the order and colors with a STYLEATTRS statement.

Since you are using lines and markers the specific element you want to override is the DATACONTRASTCOLORS.

Try adding:

styleattrs datacontrastcolors=(green blue);

The first group value encountered should get green lines and markers and the second would be blue. If the order isn't as desired then switch them in the statement. Note that the third or other group values will still have the default colors.

If you want to modify the colors slightly you can use words like bright, dark, light (and a few more) such as darkgreen brightblue.

Or investigate all of the color naming schemes SAS uses.

Proc SGPANEL color by subject

csa — Tue, 22 Jun 2021 17:41:31 GMT

Hi All,

I am trying to generate a figure plot using the below code. I am getting the output as in the attached screen shot.

proc sgpanel data=have ;
panelby SUBJID / layout=PANEL novarname columns=4 rows=2;
series x=x_axis_var y=aval /group=trt01p_ lineattrs=(pattern=mediumdash thickness=2);
scatter x=x_axis_var y=aval /group=trt01p_ markerattrs = (symbol=circlefilled size=8);

rowaxis integer grid values=(0,50,75,100) label="test";
colaxis integer grid values=(1 to 10 by 1) discreteorder=data label="Day";

run;
quit;

My query is how can we change the Blue color plots 'Green', Red color plots to 'Blue' and the bottom Legend with Green and Blue colors?

Proc SGPANEL color by subject

csa — Tue, 22 Jun 2021 17:12:40 GMT

Hi All,

I am trying to generate a figure plot using the below code. I am getting the output as in the attached screen shot.

proc sgpanel data=have ;
panelby SUBJID / layout=PANEL novarname columns=4 rows=2;
series x=x_axis_var y=aval /group=trt01p_ attrid=myid lineattrs=(pattern=mediumdash thickness=2);
scatter x=x_axis_var y=aval /group=trt01p_ attrid=myid markerattrs = (symbol=circlefilled size=8);

rowaxis integer grid values=(0,50,75,100) label="test";
colaxis integer grid values=(1 to 10 by 1) discreteorder=data label="Day";

run;
quit;

My query is how can we change the Blue color plots 'Green', Red color plots to 'Blue' and the bottom Legend with Green and Blue colors?

Thanks.

Re: SAS GTL: Symbol (created by SymbolChar statement) moving on Y-Axis when increasing size

Jay54 — Mon, 21 Jun 2021 15:46:14 GMT

HOFFSET, VOFFSET, SIZE, SCALE and other options can be used to control the positioning of the symbol within the bounding box. See doc at:

https://documentation.sas.com/doc/en/pgmsascdc/9.4_3.5/grstatgraph/p0cf4zbevcqzxjn19w5berzi6ocd.htm

Re: SAS GTL: Symbol (created by SymbolChar statement) moving on Y-Axis when increasing size

mborne — Mon, 21 Jun 2021 11:43:04 GMT

data WORK.PLOT ; 
  infile datalines4 dsd missover dlm=',' ;
  length DAY GEOMEAN LCLM UCLM 8. ;
  input DAY GEOMEAN LCLM UCLM ;
  datalines4 ;
1,5.851,5.721,5.983
15,10.103,8.531,11.965
29,17.723,14.523,21.628
57,25.449,20.171,32.108
71,76.898,62.926,93.972
85,119.914,101.658,141.447
;;;;
run ;

proc sql noprint ;
  select distinct DAY into :XAxisValues separated by ' ' from WORK.PLOT order by DAY ;
quit ;
%put XAxisValues: &XAxisValues. Days ;

** Style to be used for the plot ** ;
/*this SAS style can be used: STYLES.Journal;*/
ods path (PREPEND) WORK.GRAPH ;

proc template ;
  define statgraph TestSymbolChar / store=WORK.GRAPH ;
  mvar GraphTitle EmDashHexa EmDashSize XAxisValues ;
  nmvar SymVOffset ;
  dynamic XVar YMean YLowBound YUpBound ;
  begingraph ;
  symbolchar name=EmDash char=EmDashHexa / /*textattrs=(size=20pt)*/ hoffset=0 voffset=SymVOffset /*+0.1*/ ;
    entrytitle textattrs=(size=10pt weight=bold) GraphTitle ;
    layout overlay / xaxisopts=(label='Day' linearopts=(tickvaluelist=XAxisValues)) 
                     yaxisopts=(griddisplay=on type=log logopts=(base=10 Thresholdmax=1 Thresholdmin=1 minorticks=true minortickcount=8 minorgrid=true) 
                                label='Geometric Mean (95%CI)' griddisplay=on) ;
      scatterplot x=XVar y=YMean / markerattrs=(symbol=EmDash size=EmDashSize weight=bold color=black) errorbarcapshape=serif 
                                   errorbarattrs=(thickness=1pt color=black) yerrorlower=YLowBound yerrorupper=YUpBound name="GeoMean" ;
      referenceline y=77 / lineattrs=(color=red pattern=2) curvelabel='77' curvelabelattrs=(color=black size=6) ;
      referenceline y=120 / lineattrs=(color=red pattern=2) curvelabel='120' curvelabelattrs=(color=black size=6) ;
    endlayout ;
  endgraph ;
  end ;
quit ;
*** Path of the template catalogs *** ;
ods path SASUSER.TEMPLAT(UPDATE) SASHELP.TMPLMST(READ) WORK.MYTEMP(READ) WORK.GRAPH(READ) ;

%MACRO testSymbolChar(           /* Test different Symbol to show geometric mean as a straight line */
                      EmDashHexa=,  /* Hexadecimal code for symbol character */
                      EmDashSize=,  /* Size of the symbol character */
                      SymVOffset=0, /* Vertical Offset of the symbol character */
                      imagename=,   /* Name of the PNG file */
                      GraphTemplate=TestSymbolChar /* Template to use for SGRENDER */
                      ) ;
  %** SAS SGRender ** ;
  %let GraphTitle=Using &EmDashHexa. with &EmDashSize. as a size for Symbol Char ;
  %let FigureRoot=C:\Temp ;
  option center ;
  ods listing close ;
  ods graphics on / reset=index imagename="&imagename." height=10cm width=16cm noborder ;
  ods html style=styles.journal2 image_dpi=150 gpath="&FigureRoot." path="&FigureRoot." (url=none) file="output.html" ;

    %*goptions reset=all ;
    ods graphics / outputfmt=png ;
  
     proc sgrender data=WORK.PLOT template=&GraphTemplate. description='' ;
       dynamic XVar='DAY' YMean='GEOMEAN' YLowBound='LCLM' YUpBound='UCLM' ;  
     run ;

  ods html close ;
  ods graphics off ;
  ods listing ;
%MEND testSymbolChar ;
/*
%let EmDashHexa='2012'x ;* Figure Dash * ;
%let EmDashHexa='2013'x ;* En Dash * ;
%let EmDashHexa='2014'x ;* Em Dash * ;
%let EmDashHexa='2015'x ;* Horizontal Bar * ;
%let EmDashHexa='002D'x ;* Hyphen-Minus * ;
%let EmDashHexa='0336'x ;* Combining Long Stroke Overlay * ;
%let EmDashHexa='2500'x ;* Box Drawings Light Horizontal * ;
%let EmDashHexa='25AC'x ;* Black Rectangle * ;
%let EmDashHexa='A7F7'x ;* Undefined * ;
*/
%testSymbolChar(EmDashHexa=%bquote('2014'x),EmDashSize=%bquote(),imagename=TestEmDashSizeEmpty) ;
%testSymbolChar(EmDashHexa=%bquote('2014'x),EmDashSize=%bquote(12pt),imagename=TestEmDashSize12pt) ;
%testSymbolChar(EmDashHexa=%bquote('2014'x),EmDashSize=%bquote(40),imagename=TestEmDashSize40) ;

%testSymbolChar(EmDashHexa=%bquote('2015'x),EmDashSize=%bquote(),imagename=TestHBarSizeEmpty) ;
%testSymbolChar(EmDashHexa=%bquote('2015'x),EmDashSize=%bquote(12pt),imagename=TestHBarSize12pt) ;
%testSymbolChar(EmDashHexa=%bquote('2015'x),EmDashSize=%bquote(40),imagename=TestHBarSize40) ;

%testSymbolChar(EmDashHexa=%bquote('002D'x),EmDashSize=%bquote(),imagename=TestHyphenSizeEmpty) ;
%testSymbolChar(EmDashHexa=%bquote('002D'x),EmDashSize=%bquote(12pt),imagename=TestHyphenSize12pt) ;
%testSymbolChar(EmDashHexa=%bquote('002D'x),EmDashSize=%bquote(40),imagename=TestHyphenSize40) ;

%testSymbolChar(EmDashHexa=%bquote('0336'x),EmDashSize=%bquote(),imagename=TestCLSOSizeEmpty) ;
%testSymbolChar(EmDashHexa=%bquote('0336'x),EmDashSize=%bquote(12pt),imagename=TestCLSOSize12pt) ;
%testSymbolChar(EmDashHexa=%bquote('0336'x),EmDashSize=%bquote(40),imagename=TestCLSOSize40) ;

%testSymbolChar(EmDashHexa=%bquote('2012'x),EmDashSize=%bquote(),imagename=TestFigDashSizeEmpty) ;
%testSymbolChar(EmDashHexa=%bquote('2012'x),EmDashSize=%bquote(12pt),imagename=TestFigDashSize12pt) ;
%testSymbolChar(EmDashHexa=%bquote('2012'x),EmDashSize=%bquote(40),imagename=TestFigDashSize40) ;

%testSymbolChar(EmDashHexa=%bquote('2013'x),EmDashSize=%bquote(),imagename=TestEnDashSizeEmpty) ;
%testSymbolChar(EmDashHexa=%bquote('2013'x),EmDashSize=%bquote(12pt),imagename=TestEnDashSize12pt) ;
%testSymbolChar(EmDashHexa=%bquote('2013'x),EmDashSize=%bquote(40),imagename=TestEnDashSize40) ;

%testSymbolChar(EmDashHexa=%bquote('2500'x),EmDashSize=%bquote(),imagename=TestBDLHSizeEmpty) ;
%testSymbolChar(EmDashHexa=%bquote('2500'x),EmDashSize=%bquote(12pt),imagename=TestBDLHSize12pt) ;
%testSymbolChar(EmDashHexa=%bquote('2500'x),EmDashSize=%bquote(40),imagename=TestBDLHSize40) ;

%testSymbolChar(EmDashHexa=%bquote('25AC'x),EmDashSize=%bquote(),imagename=TestBlackRectizeEmpty) ;
%testSymbolChar(EmDashHexa=%bquote('25AC'x),EmDashSize=%bquote(12pt),imagename=TestBlackRectSize12pt) ;
%testSymbolChar(EmDashHexa=%bquote('25AC'x),EmDashSize=%bquote(40),imagename=TestBlackRectSize40) ;

%testSymbolChar(EmDashHexa=%bquote('A7F7'x),EmDashSize=%bquote(),imagename=TestUndefSizeEmpty) ;
%testSymbolChar(EmDashHexa=%bquote('A7F7'x),EmDashSize=%bquote(12pt),imagename=TestUndefSize12pt) ;
%testSymbolChar(EmDashHexa=%bquote('A7F7'x),EmDashSize=%bquote(40),imagename=TestUndefSize40) ;

/* Not so bad solution */
%testSymbolChar(EmDashHexa=%bquote('2500'x),EmDashSize=%bquote(20),imagename=TestBDLHSize20) ;
%testSymbolChar(EmDashHexa=%bquote('2014'x),EmDashSize=%bquote(20),SymVOffset=0.08,imagename=TestEmDashSize20Offset) ;

Re: SAS GTL: Symbol (created by SymbolChar statement) moving on Y-Axis when increasing size

ChrisNZ — Mon, 21 Jun 2021 06:49:58 GMT

Please post your code formatted, using the appropriate icon.

Re: What is the explanation behind the limited graphical capabilities of SAS?

AllanBowe — Thu, 17 Jun 2021 12:18:34 GMT

It's very easy to connect SAS to Javascript and produce incredibly interactive, beautiful graphs & charts. You can do this from Desktop SAS, SAS 9 Stored Processes, or Viya.

We use the SASjs framework extensively for this type of thing in our SAS Apps team.

Re: proc sgmap - removing white padding around edge of image

JeffMeyers — Thu, 17 Jun 2021 00:13:07 GMT

I looked through the options and didn't see any padding options. It looks like it's being put there with padding or offsets on a non-visible x/y axis. Do you know if there's any options you can put in a style template to control how much padding there is? Otherwise whoever designed the proc probably would have to add the option I would imagine? I think it I read it was made by a 3rd party. I couldn't find anyway to replicate with just GTL.

Re: proc template/ proc sgrender graph

JeffMeyers — Thu, 17 Jun 2021 00:09:09 GMT

This is how different 1-KM vs CIF can be. The top is 1-KM the bottom is CIF:

Re: proc sgmap - removing white padding around edge of image

RobertAllison_SAS — Thu, 17 Jun 2021 00:07:48 GMT

Just so everyone's clear on what this example is doing ... the user's "map" is the rectangular black polygon (they specified 5 lat/long coordinates in their map dataset), and then Proc Sgmap automatically determines which Openstreetmap tiles to put behind it. I'm not 100% certain whether Sgmap has to use whole tiles, or if it 'trims' the tiles. In this case the black rectangle is the user's map polygon, not the border of the page. None of these details shed any light on the user's actual question, but thought I'd explain, just in case you were curious or confused.

Per the user's question about having the Sgmap go all the way to the edge of the available space, so that there's absolutely no "white space" around the edge ... I don't know of any way to do that. I'm not saying it's "impossible" but I don't know of a way.

Re: proc template/ proc sgrender graph

JeffMeyers — Wed, 16 Jun 2021 23:57:35 GMT

The macro (%newsurv) will do them for you if you want to have them with a macro call like:

data BMT;
        input DIAGNOSIS Ftime Status Gender@@;
        label Ftime="Days";
        format Diagnosis grpLabel.;
datalines;
1       2081       0       1       1       1602    0       1
1       1496       0       1       1       1462    0       0
1       1433       0       1       1       1377    0       1
1       1330       0       1       1       996     0       1
1       226        0       0       1       1199    0       1
1       1111       0       1       1       530     0       1
1       1182       0       0       1       1167    0       0
1       418        2       1       1       383     1       1
1       276        2       0       1       104     1       1
1       609        1       1       1       172     2       0
1       487        2       1       1       662     1       1
1       194        2       0       1       230     1       0
1       526        2       1       1       122     2       1
1       129        1       0       1       74      1       1
1       122        1       0       1       86      2       1
1       466        2       1       1       192     1       1
1       109        1       1       1       55      1       0
1       1          2       1       1       107     2       1
1       110        1       0       1       332     2       1
2       2569       0       1       2       2506    0       1
2       2409       0       1       2       2218    0       1
2       1857       0       0       2       1829    0       1
2       1562       0       1       2       1470    0       1
2       1363       0       1       2       1030    0       0
2       860        0       0       2       1258    0       0
2       2246       0       0       2       1870    0       0
2       1799       0       1       2       1709    0       0
2       1674       0       1       2       1568    0       1
2       1527       0       0       2       1324    0       1
2       957        0       1       2       932     0       0
2       847        0       1       2       848     0       1
2       1850       0       0       2       1843    0       0
2       1535       0       0       2       1447    0       0
2       1384       0       0       2       414     2       1
2       2204       2       0       2       1063    2       1
2       481        2       1       2       105     2       1
2       641        2       1       2       390     2       1
2       288        2       1       2       421     1       1
2       79         2       0       2       748     1       1
2       486        1       0       2       48      2       0
2       272        1       0       2       1074    2       1
2       381        1       0       2       10      2       1
2       53         2       0       2       80      2       0
2       35         2       0       2       248     1       1
2       704        2       0       2       211     1       1
2       219        1       1       2       606     1       1
3       2640       0       1       3       2430    0       1
3       2252       0       1       3       2140    0       1
3       2133       0       0       3       1238    0       1
3       1631       0       1       3       2024    0       0
3       1345       0       1       3       1136    0       1
3       845        0       0       3       422     1       0
3       162        2       1       3       84      1       0
3       100        1       1       3       2       2       1
3       47         1       1       3       242     1       1
3       456        1       1       3       268     1       0
3       318        2       0       3       32      1       1
3       467        1       0       3       47      1       1
3       390        1       1       3       183     2       0
3       105        2       1       3       115     1       0
3       164        2       0       3       93      1       0
3       120        1       0       3       80      2       1
3       677        2       1       3       64      1       0
3       168        2       0       3       74      2       0
3       16         2       0       3       157     1       0
3       625        1       0       3       48      1       0
3       273        1       1       3       63      2       1
3       76         1       1       3       113     1       0
3       363        2       1
;
run;

%newsurv(data=bmt,time=ftime,cens=status,class=diagnosis, method=cif,ev_vl=1, summary=0, gpath=~/ibm/,
    risklist=0 to 2500 by 500);

The code that runs in the background would look something like this (it calculates the N at risk manually):

proc lifetest data=bmt alpha=0.05 alphaqt=0.05 cifvar error=aalen 
        outcif=_surv (where=((event>. or t1=0 or c1=1)) 
                      rename=(stratum=stratumnum ftime=t1 cif=s1 censored=c1 cif_lcl=lcl1 cif_ucl=ucl1 variance=vcif) 
                      keep=cif ftime censored event atrisk cif_lcl cif_ucl variance stratum) 
        conftype=LOG;
    strata diagnosis;
    time ftime * status(0) / failcode=1;
run;

data _splot;
    set _surv;
    by stratumnum;
    array _risktimes_ {6} (0, 500, 1000, 1500, 2000, 2500);
    retain _ncens _nevents _lagncens _lagnevents;

    if first.stratumnum then do;
        _ncens=0;
        _nevents=0;
        _lagncens=0;
        _lagnevents=0;
        _count_=1;
    end;

    if _count_ le dim(_risktimes_) then do;
        if t1 <=_risktimes_{_count_} then do;
            if event>. then _nevents=_nevents+event;

            if c1>. then _ncens=_ncens+c1;
        end;
        else do;
            if event>. then _lagnevents=_lagnevents+event;

            if c1>. then _lagncens=_lagncens+c1;
        end;
    end;

    if _count_ le dim(_risktimes_) then do;
        if t1 >=_risktimes_(_count_) then do until(x=1);
            tatrisk=_risktimes_(_count_);
            time=tatrisk;
            call missing(event, c1);
            output;
            _nevents=_nevents+_lagnevents;
            _ncens=_lagncens+_ncens;
            _lagnevents=0;
            _lagncens=0;
            _count_+1;

            if _count_>dim(_risktimes_) then x=1;
            else if t1 < _risktimes_(_count_) then x=1;
            else x=0;
        end;

        if last.stratumnum then do i=_count_ to dim(_risktimes_);
            tatrisk=_risktimes_(_count_);
            time=tatrisk;
            atrisk=0;
            call missing(event, c1);
            output;
            _nevents=_nevents+_lagnevents;
            _ncens=_lagncens+_ncens;
            _lagnevents=0;
            _lagncens=0;
        end;
    end;
    keep tatrisk time stratumnum atrisk event c1 t1 _count_ _nevents  _ncens _lagnevents _lagncens;
    rename c1=censored;
run;

Re: proc template/ proc sgrender graph

S_RAVI — Wed, 16 Jun 2021 23:51:53 GMT

So what option do I have to use for obtaining Atrisk?

Re: proc template/ proc sgrender graph

S_RAVI — Wed, 16 Jun 2021 23:49:41 GMT

My event variable has 0 - censored,1- progression, 2- death values

Re: proc template/ proc sgrender graph

JeffMeyers — Wed, 16 Jun 2021 23:45:14 GMT

They are only the same when you have one event and a censor value. If your event variable ever has competing risks (e.g. has values of 0, 1, 2, 3 or something) then they will be very different.