ods listing close;
ods pdf file="D:\Data\SPARCS\reportcard\outputfile.pdf"  style=SASdocprinter notoc;

PROC REPORT DATA=rptcrd.inputfile
            nowindows headline headskip split='*' style(header)=[fontsize=1] style(report)=[fontsize=1] style(report)=[fontsize=1] ;
options number nonumber nodate center missing=' ' orientation = landscape;

LABEL claim_type = "Claim Type ";

BY DESCENDING claim_type;

column facility_name pfi CFI_PT_ind homelessind pfidisppctind ipdxprscrcrd opdxprscrcrd 
       pntoforgn_scrcrd pntoforgnnb_scrcrd dischhrind eth_scrcrd race_scrcrd racespec_scrcrd;

  define facility_name / display "Facility*Name" width=70 style(column)=[fontsize=1];
  define pfi           / id "PFI" width=6 style(column)=[fontsize=1];
  define CFI_PT_ind    / display "CFI/Payment*Typology Issue1" width=1 style(column)=[fontsize=1];
  define homelessind   / display "County/Homeless*Issue2" width=1 style(column)=[fontsize=1];
  define pfidisppctind / display "Patient*Disposition*Issue3" width=1 style(column)=[fontsize=1];
  define ipdxprscrcrd  / display "Inpatient*Diag and*Proc Issue4" width=1 style(column)=[fontsize=1];
  define opdxprscrcrd  / display "Outpatient*Diag and*Proc Issue5" width=1 style(column)=[fontsize=1];
  define pntoforgn_scrcrd / display "Point of*Origin Issue6" width=1 style(column)=[fontsize=1];
  define pntoforgnnb_scrcrd / display "Point of*Origin*(Newborn) Issue7" width=1 style(column)=[fontsize=1];
  define dischhrind    / display "Discharge*Hour*Issue8" width=1 style(column)=[fontsize=1];
  define eth_scrcrd    / display "Ethnicity*Issue9" width=1 style(column)=[fontsize=1];
  define race_scrcrd   / display "Race*Issue10" width=1 style(column)=[fontsize=1];
  define racespec_scrcrd / display "Race*Specificity*Issue11" width=1 style(column)=[fontsize=1]; 

* MOD function to determine if row is odd or even;

COMPUTE facility_name;
  line_count + 1;
    IF MOD(line_count,2) = 0 THEN DO;
	   CALL DEFINE(_row_,"style","style={background = LIGR}");
	   END;
    ENDCOMP;

COMPUTE after _PAGE_ / LEFT;

LINE "CLAIM TYPE: I = Inpatient, E = Emergency Room, A = Ambulatory Surgery";
LINE "1 Indicator signifies possible mis-match between Claim Filing Indicator and Payer Topology";
LINE "2 Indicator signifies County=99 greater than 20% Total Discharges and Residence Indicator=H greater than Address=Homeless";
LINE "3 Indicator signifies 100% of discharges, greater than 10, were to HOME";
LINE "4 Indicator signifies Average Number of Inpatient Diagnosis or Average Number of Procedures is below 10th percentile within Region";
LINE "5 Indicator signifies Average Number of Outpatient Diagnosis or Average Number of Procedures is below 10th percentile within Region";
LINE "6 Indicator signifies incorrect codes populate point of origin data field";
LINE "7 Indicator signifies incorrect codes populate point of origin data field (Newborns Only)";
LINE "8 Indicator signifies discharge hour reported is greater than 50% of all the discharge hours reported";
LINE "9 Indicator signifies a facility with 1) Combined Hispanic rate of 0% or 2) Unknown rate of 100%";
LINE "10 Indicator signifies a facility with either an OTHER rate of 100% or Total Discharges are greater than 200 and the WHITE rate is 100%";
LINE "11 Indicator signifies a facility where the number of discharges for either Asian, Native Hawaiian/Pacific Islander";
LINE "                                              or Multi are greater than 50 and the coresponding 'Specific' equals 0"; 

ENDCOMP;

footnote1 bold font=times color=black h=2 J=L "Report Date: %sysfunc(putn("&sysdate"d,mmddyy10.))";
RUN;

ods pdf close;
ods listing;