ods path work.templat(update) sasuser.templat(read)  sashelp.tmplmst(read);
proc template;
define style styles.mystyle;
 parent = styles.egdefault;
 class header, data/
   font_face   = "arial, helvetica, sans-serif"
   font_size   = 9pt
   font_weight = bold
   font_style  = roman
   foreground  = red
   background  = CXFFFFFF;
 class data /
    font_weight = medium
    foreground  = black;
end;
run;
options leftmargin=0.2in rightmargin=0.2in topmargin=0.2in bottommargin=0.2in;
ods tagsets.excelxp
file  = "C:\Users\Desktop\shoes_test.xls"
style = styles.mystyle
options (orientation    ='landscape'
         autofit_height ='yes'
         );
ods escapechar='~';
PROC REPORT DATA=SASHELP.SHOES(obs=5)  SPLIT="/" nowd ;
COLUMN  ("EAST COAST" "Eastern States~{super 1}" Region Product Subsidiary)
        ("WEST COAST" "Western Stores~{super 2}" Sales Inventory Returns );
DEFINE  Region     / DISPLAY  "Region~{super 3}" ;
DEFINE  Product    / DISPLAY  "Product" ;
DEFINE  Subsidiary / DISPLAY  "Subsidiary" ;
DEFINE  Sales      / SUM      "Total Sales" ;
DEFINE  Inventory  / SUM      "Total Inventory" ;
DEFINE  Returns    / SUM      "Total Returns"  style(header)={background=light grey};
RUN;
ods tagsets.excelxp close;