assign the same value by group

[Jedrzej]

ID	var1	var2	var3
ID 00		Y
ID 00
ID 00	Y
ID 01	Y		Y
ID 01

Hi  i have this table and I want to assign the same value to all vars by ID if I find "Y"

so it should be like

ID	var1	var2	var3
ID 00	Y	Y
ID 00	Y	Y
ID 00	Y	Y
ID 01	Y		Y
ID 01	Y		Y

thank you for your help

[Shmuel]

Try next code:

data want;
 set have;
  by ID;  /* assumed data is sorted by ID */
      retain v1 v2 v3;  /* or v1-v3 */
      if first.ID then do;
         v1=var1; v2=var2; v3=var3; /* can be done by an array and a loop */
      end;
      var1=v1; var2=v2; var3=v3;
run;

[PeterClemmensen]

There you go

data have;
infile datalines dlm=',' dsd;
input ID $ var1 $ var2 $ var3 $;
datalines;
ID 00, ,Y,  
ID 00, , ,  
ID 00,Y, ,  
ID 01,Y, ,Y 
ID 01, , ,  
;

data want;
   update have(obs=0) have;
   by ID;
   output;
run;

Result:

ID     var1  var2  var3 
ID 00        Y       
ID 00        Y       
ID 00  Y     Y       
ID 01  Y           Y 
ID 01  Y           Y 

[Peter_C]

I don't understand how that update statement knows that VAR1 should be set to Y on the first row ouput.
Same problem for row4 and VAR3

[Peter_C]

Row4 is not at same problem as Row1. Sorry

[Ksharp]

If data like this , you code wouldn't work.

data have;
infile datalines dlm=',' dsd;
input ID $ var1 $ var2 $ var3 $;
datalines;
ID 00, , , 
ID 00, ,Y,   
ID 00,Y, ,  
ID 01,Y, ,Y 
ID 01, , ,  
;

[PeterClemmensen]

As stated below, I am aware 🙂 @Astoundings correction does the trick

[Astounding · Accepted solution]

Here's an approach.  You might have to adjust for the actual variables you have in real life, and which ones should be replicated across observations:

data want;
   do until (last.id);
      update have(obs=0) have;
      by ID;
   end;
   do until (last.id);
      set have (keep=id);
      by id;
      output;
   end;
run;

The top loop accumulates the variable values, then the bottom loop outputs the appropriate number of times.

[ramgouveia]

@Astounding 

And if instead of one variable to group by I have two or more?

Thnk you.

[Astounding]

It depends on what you mean when you say you have two or more variables.  So give an example.  Certainly the BY statement supports multiple variables, but the outcome might not be what you have in mind.

[PeterClemmensen]

@Jedrzej My bad, I misread the question. @Astoundings correction is the way to go.