@Quentin, that request is simple enough...
filename foo url "https://www.sas.com/content/sascom/en_us/events/sas-global-forum/program/proceedings/jcr:content/par/styledcontainer_1306083555/par/tabwrapper/tabwrapperpar/tab/tabpar/styledcontainer/par/listgrouppdf.ajaxlist.html";
%macro getPaper(url);
%local big small;
%let big=%scan(&url,-1,/);
%let small=%scan(&big,1,-);
filename _&small "%sysfunc(pathname(work,l))\&big";
proc http url="&url" method='get' out=_&small;
run;
ods package(pckg) add file=_&small;
%mend;
*filename pckg "%sysfunc(pathname(work,l))\sgf2018.zip";
ods package(pckg) open nopf;
data _null_;
length pdf $1024.;
infile foo dsd dlm=' ';
input @'<a href=' pdf :;
if substr(pdf,max(lengthn(pdf)-2,1))='pdf';
call execute('%nrstr(' || '%getPaper(' || trim(pdf) || ')' || ')');
run;
ods package(pckg) publish archive
properties(
archive_name='sgf2018.zip'
archive_path="%sysfunc(pathname(work,l))"
);
ods package(pckg) close;
filename _all_ clear;
In case anyone was wondering... by uncompressed file size, the biggest paper is:
E-Poster 2876
Predictive Modeling of the Journey from H-1B to Permanent US Work Visa by Shibbir Khan, Clark University, Graduate School of Management, Worcester, MA, USA
and the smaller is:
Breakout 1778
A Macro for Ensuring Data Integrity When Converting SAS® Data Sets by Richard D. Langston, SAS Institute Inc.
and the highest compression ratio
E-Poster 1664
Weather Data Cleansing for Electrical Load Forecasting by Aubrey Condor, University of Central Florida
and the largest compressed file size
Breakout 2910
Getting Started with Survival Analysis Course Notes by Marc Huber, SAS Institute, Inc.
The resulting zip file is is about 311Mb and contains 427 pdfs
