Hi ,
Below is the graph im intended to create. As tyou can see it is stacked and grouped and subgrouped with 100% bars.
Im using the following code, but not sure how to achieve the colours and the patterns. Also would like to present the N values at the bottom of each bars. I tried xaxis table ,but it gives all the bar values together at the bottom of each bars. I pre-calulated the n-values and tried giving the 'N=' along with the vbar variable by concatenating, but the result was same as that of xolaxistable.
my code below:
proc sgpanel data=ip pctlevel=group;
panelby avisit / layout=columnlattice onepanel novarname noborder colheaderpos=top headerattrs=(Size=8) ;
vbar trt01p / group=avalc stat=percent ;
colaxis display=(nolabel) fitpolicy=split splitchar='-' valueattrs=(size=8);
rowaxis grid;
* colaxistable /classdisplay=cluster position=bottom valueattrs=(size=2 color=blue) stat=sum ;
run;
run;
I did a generic example with the CARS data set since I don't have your data. Let me know if this helps:
proc sort data=sashelp.cars out=cars;
by origin drivetrain type;
run;
proc freq data=cars noprint;
by origin drivetrain;
table type / out=freq;
run;
proc sql;
create table counts as
select origin,drivetrain,catx('`',drivetrain, '(N='||strip(put(sum(count),12.0))||')') as n from freq
group by origin,drivetrain;
quit;
data plot;
merge freq counts;
by origin drivetrain;
label n = 'Drive Train';
run;
proc sgpanel data=plot;
panelby origin /layout=columnlattice onepanel rows=1 novarname noheaderborder colheaderpos=bottom
headerattrs=(Size=8) uniscale=row ;
colaxis splitchar='`' display=(nolabel) ;
vbarparm category=n response=percent/ group=type fillpattern;
run;
In this answer the PANELBY is TIMEFRAME, VBAR is TREATMENT, and / GROUP= is THERAPY
The core issue is that /GROUP THERAPY values are driving the patterning. These values and their patterns appear in the legend. The categorical data set has the fully expected situation that THERAPY values encountered in one TREATMENT will be the same as encountered in a different TREATMENT. This means the THERAPY based patterning can not accommodate the TREATMENT it is under and thus can not drive color differentiation.
Let's simulate some data so others can play along. The therapy value is coded 0 to 7 and the timeframe is code 0 to 3:
proc format;
value timeframe
0 = 'Baseline iron use'
1 = 'Day 1 : Week 12'
2 = 'Week 12 : Week 24'
3 = 'Week 24 : Week 36'
;
value therapy
0 = 'None'
1 = 'Only IV'
2 = 'Only Oral'
3 = 'Only Other'
4 = 'Both IV + Oral'
5 = 'Both IV + Other'
6 = 'Both Oral + Other'
7 = 'All IV + Oral + Other'
;
run;
data have(keep=patid--timeframe);
top = 400;
call streaminit(1234);
length patid 8 treatment $8 therapy 8 timeframe 8 ;
do treatment = 'Dapro', 'rhEPO';
* 400 Dapro, 600 rhEPO;
do i = 1 to top;
patid + 1;
p = rand('uniform', 100);
select;
when (p < 40.0) therapy = 0;
when (p < 85.0) therapy = 1;
when (p < 92.0) therapy = 2;
when (p < 93.5) therapy = 3;
when (p < 95.0) therapy = 4;
when (p < 96.5) therapy = 5;
when (p < 98.0) therapy = 6;
otherwise therapy = 7;
end;
do timeframe = 0 to 3;
* simulate a 3% patient drop out at any timeframe;
if rand('uniform') < 0.03 then leave;
* simulate an entire bar segment with no patients;
if treatment = 'rhEPO' and timeframe = 3 and therapy = 1 then leave;
output;
end;
end;
top + 200;
end;
format
timeframe timeframe.
therapy therapy.
;
run;
Take a look at the simplest first try that uses STYLE=JOURNAL2 for its grayscale theme:
ods html path='.' file='vbar.html' style=Journal2;
proc sgpanel data=have pctlevel=group;
title 'Simple Starter Plot';
panelby timeframe /
layout=columnlattice
onepanel
;
vbar treatment /
group=therapy
stat=percent
;
run;
The attached code shows the steps and some intermediate plots demonstrating the transition to a final plot with desired features. The pre plot processing includes:
- Creating a custom template named StackedVbarGroupCrossVar based on Journal2
- The first eight GraphData styles elements (for the 8 therapies) specify the cross hatch patterns to use
- Another eight GraphData style elements specify the same hatching with ContrastColor=LIGHTRED
- Creating a custom format THERAPY_CROSS_TREATMENT to deal with a transformed value of THERAPY that accounts for TREATMENT
- Computing the counts for each TREATMENT & TIMEFRAME combination
- Create a PLOT data set that has
- New column BAR_COUNT that contain the computed counts
- New column THERAPY_CROSS_TREATMENT that segregates therapy according to TREATMENT (Dapro nochange, rhEPO therapy code+10)
- New column TREATMENT_WITH_COUNT that has "/(N=<combination-count>)" concatenated to TREATMENT
The tweaked data now has everything needed tricking out the plot into a final presentation created using the custom template StackedVbarGroupCrossVar:
- Compute a quoted list of the rhEPO specific THERAPY_CROSS_TREATMENT formatted values so they can be EXCLUDEd from the KEYLEGEND
- Add PANELBY options:
- novarname
noborder
colheaderpos=bottom
headerbackcolor=white
noheaderborder
uniscale=row (not having uniscale col will let proc remove 'nobar' ticks)
- novarname
- Change the VBAR statement to use tweaked values
- vbar treatment_with_count /
group=therapy_cross_treatment ...
- vbar treatment_with_count /
- Update the KEYLEGEND to exclude the segregating group values beyond the first eight
- keylegend / ... exclude=(&keyexcludes)
- Add a rowaxis to display 10% intervals
- rowaxis values = (0 to 1 by 0.1) ... ;
- Add a colaxis with splitalways so the combination count (the bar total counts) appears below the TREATMENT
proc sgpanel data=plot pctlevel=group;
title 'Presentation Plot Final';
panelby timeframe /
layout=columnlattice
onepanel
novarname
noborder
colheaderpos=bottom
headerbackcolor=white
noheaderborder
uniscale=row
;
vbar treatment_with_count /
group=therapy_cross_treatment
stat=percent
;
label therapy_cross_treatment = 'Iron therapy';
keylegend /
across=4
outerpad=14px
noborder
exclude=(&keyexcludes)
;
rowaxis
values = (0 to 1 by 0.1)
display=(noline noticks)
grid
;
colaxis
display=(nolabel)
fitpolicy=splitalways
splitchar='/'
valueattrs=(size=8pt)
;
run;
Learn how use the CAT functions in SAS to join values from multiple variables into a single value.
Find more tutorials on the SAS Users YouTube channel.
Click image to register for webinar
Classroom Training Available!
Select SAS Training centers are offering in-person courses. View upcoming courses for:
-
4776 views
-
4 likes
-
-
